sys-boot/egrub/egrub-0.97.ebuild

egrub-0.97.ebuild (text/plain), 7.26 KB, created by Mario Fetka (geos_one) on 2010-11-15 18:31:33 UTC

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-boot/grub/grub-0.97-r10.ebuild,v 1.6 2010/09/02 21:19:37 robbat2 Exp $

# XXX: we need to review menu.lst vs grub.conf handling.  We've been converting
#      all systems to grub.conf (and symlinking menu.lst to grub.conf), but
#      we never updated any of the source code (it still all wants menu.lst),
#      and there is no indication that upstream is making the transition.

EAPI=2

inherit mount-efi eutils flag-o-matic toolchain-funcs autotools linux-info pax-utils

PATCHVER="1.0" # Should match the revision ideally
DESCRIPTION="GNU GRUB Legacy boot loader EFI Edition"
HOMEPAGE="http://www.gnu.org/software/grub/"
SRC_URI="mirror://gentoo/grub-${PV}.tar.gz
	ftp://alpha.gnu.org/gnu/${PN}/grub-${PV}.tar.gz
	mirror://gentoo/splash.xpm.gz
	mirror://gentoo/${P}-patches-${PATCHVER}.tar.bz2
	http://ftp.disconnected-by-peer.at/efi/${P}-patches-${PATCHVER}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="custom-cflags"

DEPEND="sys-boot/gnu-efi
	!sys-boot/grub"
RDEPEND="sys-boot/efibootmgr
	sys-fs/dosfstools"
PROVIDE="virtual/bootloader"

S="${WORKDIR}"/grub-${PV}

#pkg_setup() {
#	local arch="$(tc-arch)"
#	case ${arch} in
#		amd64) CONFIG_CHECK='~IA32_EMULATION' check_extra_config ;;
#	esac
#}

src_prepare() {
	# patch breaks booting for some people #111885
#	rm "${WORKDIR}"/patch/400_*reiser4*

	if [[ -n ${PATCHVER} ]] ; then
		EPATCH_SUFFIX="patch"
		EPATCH_FORCE="yes" epatch "${WORKDIR}"/patch
	fi

	sed -e "s/^gnuefi_path=.*$/gnuefi_path=\/usr\/$(get_libdir)/g" \
	    -e "s/^LIBGNUEFI=.*$/LIBGNUEFI=\/usr\/$(get_libdir)\/libgnuefi.a/g" \
	    -i "${S}"/configure.in || die "failed to hack gnu-efi path"

	# rename grub tools to not interfer with grub
	epatch "${FILESDIR}"/grub-0.97-grub-set-default-1.patch

	# Grub will not handle a kernel larger than EXTENDED_MEMSIZE Mb as
	# discovered in bug 160801. We can change this, however, using larger values
	# for this variable means that Grub needs more memory to run and boot. For a
	# kernel of size N, Grub needs (N+1)*2.  Advanced users should set a custom
	# value in make.conf, it is possible to make kernels ~16Mb in size, but it
	# needs the kitchen sink built-in.
	local t="custom"
	if [[ -z ${GRUB_MAX_KERNEL_SIZE} ]] ; then
		case $(tc-arch) in
			amd64) GRUB_MAX_KERNEL_SIZE=9 ;;
			x86)   GRUB_MAX_KERNEL_SIZE=5 ;;
		esac
		t="default"
	fi
	einfo "Grub will support the ${t} maximum kernel size of ${GRUB_MAX_KERNEL_SIZE} Mb (GRUB_MAX_KERNEL_SIZE)"

	sed -i \
		-e "/^#define.*EXTENDED_MEMSIZE/s,3,${GRUB_MAX_KERNEL_SIZE},g" \
		"${S}"/grub/asmstub.c \
		|| die "Failed to hack memory size"

	eautoreconf
}

src_configure() {
	filter-flags -fPIE #168834

	unset BLOCK_SIZE #73499

	### i686-specific code in the boot loader is a bad idea; disabling to ensure
	### at least some compatibility if the hard drive is moved to an older or
	### incompatible system.

	# grub-0.95 added -fno-stack-protector detection, to disable ssp for stage2,
	# but the objcopy's (faulty) test fails if -fstack-protector is default.
	# create a cache telling configure that objcopy is ok, and add -C to econf
	# to make use of the cache.
	#
	# CFLAGS has to be undefined running econf, else -fno-stack-protector detection fails.
	# STAGE2_CFLAGS is not allowed to be used on emake command-line, it overwrites
	# -fno-stack-protector detected by configure, removed from netboot's emake.
	use custom-cflags || unset CFLAGS

	export grub_cv_prog_objcopy_absolute=yes #79734

	# Now build the regular grub
	# Note that FFS and UFS2 support are broken for now - stage1_5 files too big
	econf \
		--libdir=/lib \
		--datadir=/usr/lib/grub \
		--exec-prefix=/ \
		--disable-auto-linux-mem-opt \
		--with-platform=efi \
		--without-curses \
		|| die "econf failed"
}

src_compile() {
	emake || die "making regular stuff"
}

src_test() {
	# non-default block size also give false pass/fails.
	unset BLOCK_SIZE
	make check || die "make check failed"
}

src_install() {
	emake DESTDIR="${D}" install || die

	# bug 330745
	pax-mark -m "${D}"/sbin/grub

	# dont install not needed files
	rm -rf "${D}"/usr/lib
	rm -rf "${D}"/usr/share/man/man1
	rm "${D}"/usr/share/man/man8/grub-install.8

	dodoc AUTHORS BUGS ChangeLog NEWS README THANKS TODO
	newdoc docs/menu.lst grub.conf.sample
	dodoc "${FILESDIR}"/grub.conf.gentoo
	prepalldocs

	insinto /usr/share/grub
	doins "${DISTDIR}"/splash.xpm.gz
	doins efi/grub.efi
}

setup_efi_dir() {
	local boot_dir=$1
	local dir=${boot_dir}

	mkdir -p "${dir}"
	# fatxx and links ?
	#[[ ! -L ${dir}/boot ]] && ln -s . "${dir}/boot"
	dir="${dir}/grub"
	if [[ ! -e ${dir} ]] ; then
		mkdir "${dir}" || die "${dir} does not exist!"
	fi

	# change menu.lst to grub.conf
	if [[ ! -e ${dir}/grub.conf ]] && [[ -e ${dir}/menu.lst ]] ; then
		mv -f "${dir}"/menu.lst "${dir}"/grub.conf
		ewarn
		ewarn "*** IMPORTANT NOTE: menu.lst has been renamed to grub.conf"
		ewarn
	fi

	# fatxx and links ?
	#if [[ ! -e ${dir}/menu.lst ]]; then
	#	einfo "Linking from new grub.conf name to menu.lst"
	#	ln -snf grub.conf "${dir}"/menu.lst
	#fi

	#einfo "Copying files from /lib/grub, /usr/lib/grub and /usr/share/grub to ${dir}"
	einfo "Copying files from /usr/share/grub to ${dir}"
	for x in \
		"${ROOT}"/usr/share/grub/* ; do
		[[ -f ${x} ]] && cp -p "${x}" "${dir}"/
	done
#		"${ROOT}"/lib*/grub/*/* \
#		"${ROOT}"/usr/lib*/grub/*/* \

	if [[ ! -e ${dir}/grub.conf ]] ; then
		s="${ROOT}/usr/share/doc/${PF}/grub.conf.gentoo"
		[[ -e "${s}" ]] && cat "${s}" >${dir}/grub.conf
		[[ -e "${s}.gz" ]] && zcat "${s}.gz" >${dir}/grub.conf
		[[ -e "${s}.bz2" ]] && bzcat "${s}.bz2" >${dir}/grub.conf
	fi

	# Per bug 218599, we support grub.conf.install for users that want to run a
	# specific set of Grub setup commands rather than the default ones.
	grub_config=${dir}/grub.conf.install
	[[ -e ${grub_config} ]] || grub_config=${dir}/grub.conf
	if [[ -e ${grub_config} ]] ; then
		egrep \
			-v '^[[:space:]]*(#|$|default|fallback|initrd|password|splashimage|timeout|title)' \
			"${grub_config}" | \
		/sbin/grub --batch \
			--device-map="${dir}"/device.map \
			> /dev/null
	fi

	# the grub default commands silently piss themselves if
	# the default file does not exist ahead of time
	if [[ ! -e ${dir}/default ]] ; then
		grub-set-default --root-directory="${boot_dir}" default
	fi
	einfo "Grub has been installed to ${boot_dir} successfully."
}

pkg_postinst() {
	if [[ -n ${DONT_MOUNT_EFI} ]]; then
		elog "WARNING: you have DONT_MOUNT_EFI in effect, so you must apply"
		elog "the following instructions for your /boot/efi!"
		elog "Neglecting to do so may cause your system to fail to boot!"
		elog
	else
		setup_efi_dir "${ROOT}"/boot/efi/EFI
		# Trailing output because if this is run from pkg_postinst, it gets mixed into
		# the other output.
		einfo ""
	fi
	elog "To interactively install grub files to another device such as a USB"
	elog "stick, just run the following and specify the directory as prompted:"
	elog "   emerge --config =${PF}"
	elog "Alternately, you can export GRUB_ALT_INSTALLDIR=/path/to/use to tell"
	elog "grub where to install in a non-interactive way."

}

pkg_config() {
	local dir
	if [ ! -d "${GRUB_ALT_INSTALLDIR}" ]; then
		einfo "Enter the directory where you want to setup grub:"
		read dir
	else
		dir="${GRUB_ALT_INSTALLDIR}"/EFI
	fi
	setup_efi_dir "${dir}"
}