ebuild

opendpi-netfilter-wrapper-1.1.ebuild (text/plain), 1.62 KB, created by Peter on 2010-11-13 13:12:44 UTC

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="2"

inherit linux-mod eutils

OPENDPI_VER="opendpi-1.2.0"
DESCRIPTION="Netfilter wrapper for OpenDPI library."
HOMEPAGE="http://opendpi.org/"
SRC_URI="http://opendpi.googlecode.com/files/${P}.tar.gz
	http://opendpi.googlecode.com/files/${OPENDPI_VER}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

RDEPEND="net-firewall/iptables"
DEPEND="${RDEPEND}"

RESTRICT="mirror"

MODULE_NAMES="xt_opendpi(extra:${S}/wrapper:${S}/wrapper/src)"
BUILD_TARGETS=" "

CONFIG_CHECK="NETFILTER NF_CONNTRACK_EVENTS !NF_CT_NETLINK"
ERROR_NETFILTER="${PN} requires Netfilter support in your kernel."
ERROR_NF_CONNTRACK_EVENTS="${PN} requires Connection tracking events support in your kernel."
ERROR_NF_CT_NETLINK="${PN} requires disabled Connection tracking netlink interface option in your kernel."

src_prepare() {
	cd "${WORKDIR}/${OPENDPI_VER}"
	epatch "${S}/ipq_main.h.diff"
	epatch "${S}/ipq_protocols.h.diff"

	cd "${S}/wrapper"
	epatch "${FILESDIR}/${P}_2.6.35_v2.patch"
}

src_compile() {
	export OPENDPI_PATH="${WORKDIR}/${OPENDPI_VER}"
	linux-mod_src_compile
}

src_install() {
	if has_version '>=net-firewall/iptables-1.4.1' ; then
		exeinto /$(get_libdir)/xtables
	else
		exeinto /$(get_libdir)/iptables
	fi
	doexe "${S}/wrapper/ipt/libxt_opendpi.so"

	dodoc "${S}/wrapper/README"
	dodoc "${S}/wrapper/INSTALL"
	dodoc "${S}/wrapper/AUTHORS"

	linux-mod_src_install
}

pkg_postinst() {
	linux-mod_pkg_postinst

	einfo
	einfo "See output of 'iptables -m opendpi --help' for help on using and the options available."
	einfo
}