fluidsynth-1.1.3.ebuild

fluidsynth-1.1.3.ebuild (text/plain), 2.09 KB, created by Gavin Pryke on 2010-11-01 14:39:53 UTC

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=2

inherit cmake-utils

IUSE="alsa debug dbus jack ladspa lash portaudio pulseaudio readline sndfile"

DESCRIPTION="Fluidsynth is a software real-time synthesizer based on the Soundfont 2 specifications."
HOMEPAGE="http://www.fluidsynth.org/"
SRC_URI="http://savannah.nongnu.org/download/fluid/${P}.tar.gz"

LICENSE="LGPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"

RDEPEND="
	>=dev-libs/glib-2.6.5
	dbus? ( >=sys-apps/dbus-1.2.24 )
	jack? ( media-sound/jack-audio-connection-kit )
	ladspa? ( >=media-libs/ladspa-sdk-1.12
		  >=media-libs/ladspa-cmt-1.15 )
	alsa? ( media-libs/alsa-lib
		lash? ( >=media-sound/lash-0.5 ) )
	pulseaudio? ( >=media-sound/pulseaudio-0.9.8 )
	portaudio? ( >=media-libs/portaudio-19_pre )
	readline? ( sys-libs/readline )
	sndfile? ( media-libs/libsndfile )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig"

CMAKE_VERBOSE=1

# Alsa is required for lash support in this package.
pkg_setup() {
	if use lash && ! use alsa; then
		ewarn "ALSA support is required for lash support to be enabled."
		ewarn "Continuing with lash support disabled."
	fi
}

src_configure() {
	local mycmakeargs=(
		$(cmake-utils_use alsa enable-alsa)
		$(cmake-utils_use dbus enable-dbus)
		$(cmake-utils_use debug enable-debug)
		$(cmake-utils_use jack enable-jack)
		$(cmake-utils_use ladspa enable-ladspa)
		$(cmake-utils_use portaudio enable-portaudio)
		$(cmake-utils_use pulseaudio enable-pulseaudio)
		$(cmake-utils_use readline enable-readline)
		$(cmake-utils_use sndfile enable-libsndfile)

		# deprecated in favour of lash
		-Denable-ladcca=0
		# no ebuild for this yet, it looks tricky
		-Denable-midishare=0
		# core{audio,midi} looks like it could be used, no mac to test
		-Denable-coreaudio=0
		-Denable-coremidi=0
		# OS/2
		-Denable-dart=0
	)

	if use alsa ; then
		mycmakeargs+=($(cmake-utils_use lash enable-lash))
	else
		mycmakeargs+=(-Denable-lash=0)
	fi

	cmake-utils_src_configure
}

src_install() {
	cmake-utils_src_install
	dodoc AUTHORS NEWS README THANKS TODO
}