telepathy-glib-0.11.11.ebuild

telepathy-glib-0.11.11.ebuild (text/plain), 1.21 KB, created by Priit Laes (IRC: plaes) on 2010-08-07 22:00:10 UTC

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="3"
PYTHON_DEPEND="2:2.5"

inherit python

DESCRIPTION="GLib bindings for the Telepathy D-Bus protocol."
HOMEPAGE="http://telepathy.freedesktop.org"
SRC_URI="http://telepathy.freedesktop.org/releases/${PN}/${P}.tar.gz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="debug introspection vala"

RDEPEND=">=dev-libs/glib-2.24
	>=dev-libs/dbus-glib-0.82
	>=dev-lang/python-2.5"

DEPEND="${RDEPEND}
	dev-libs/libxslt
	>=dev-util/gtk-doc-1.15
	>=dev-util/pkgconfig-0.21
	introspection? ( >=dev-libs/gobject-introspection-0.6.14 )
	vala? ( >=dev-lang/vala-0.9.3 )"

pkg_setup() {
	python_set_active_version 2
}

src_configure() {
	econf \
		$(use_enable debug) \
		$(use_enable debug backtrace) \
		$(use_enable debug handle-leak-debug) \
		$(use_enable introspection) \
		$(use_enable vala vala-bindings)
}

src_test() {
	if ! dbus-launch emake -j1 check; then
		die "Make check failed. See above for details."
	fi
}

src_install() {
	emake install DESTDIR="${D}" || die "emake install failed"
	dodoc AUTHORS ChangeLog NEWS README || die "dodoc failed"
}