media-gfx/sam2p-0.47 ebuild with gcc compatibility warning

sam2p-0.47.ebuild (text/plain), 1.13 KB, created by Jan Psota on 2010-04-27 13:25:48 UTC

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-gfx/sam2p/sam2p-0.47.ebuild,v 1.1 2010/04/27 14:34:28 jasiu based on ssuominen Exp $

EAPI=2

inherit toolchain-funcs eutils autotools

DESCRIPTION="Utility to convert raster images to EPS, PDF and many others"
HOMEPAGE="http://code.google.com/p/sam2p/"
SRC_URI="http://sam2p.googlecode.com/files/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="examples gif"

DEPEND="dev-lang/perl"
RDEPEND=""

RESTRICT="test"

pkg_setup() {
	if [[ $(gcc-version) > 4.4 ]]; then
		eerror "Please switch to gcc version lower than 4.5"
		die "${P} cannot be build with gcc >= 4.5 yet (#315619)"
	fi
}

src_prepare() {
	epatch "${FILESDIR}"/${PN}-0.45-{fbsd,nostrip,cflags}.patch
	eautoreconf
}

src_configure() {
	tc-export CXX
	econf --enable-lzw $(use_enable gif) || die "econf failed"
}

src_install() {
	dobin sam2p || die "Install failed"
	dodoc README
	if use examples; then
		insinto /usr/share/doc/${PF}/examples
		doins examples/*
	fi
}