mixxx with external libsoundtouch

mixxx-1.7.2-r2.ebuild (text/plain), 2.09 KB, created by Alex Barker on 2010-04-14 21:45:19 UTC

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/mixxx/mixxx-1.7.2.ebuild,v 1.2 2010/03/16 17:49:29 ssuominen Exp $

EAPI=2
inherit eutils multilib

DESCRIPTION="a QT based Digital DJ tool"
HOMEPAGE="http://mixxx.sourceforge.net"
SRC_URI="http://downloads.mixxx.org/${P}/${P}-src.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 x86"
IUSE="debug pulseaudio"

RDEPEND="media-libs/libmad
	media-libs/libid3tag
	media-libs/libmad
	media-libs/libogg
	media-libs/libvorbis
	media-libs/libsndfile
	>=media-libs/libsoundtouch-1.5
	>=media-libs/portaudio-19_pre
	virtual/opengl
	virtual/glu
	x11-libs/qt-gui:4
	x11-libs/qt-svg:4
	x11-libs/qt-opengl:4
	pulseaudio? ( media-sound/pulseaudio )"
DEPEND="${RDEPEND}
	dev-util/scons
	dev-util/pkgconfig"

pkg_setup() {
	mysconsargs="prefix=/usr
		qtdir=/usr/$(get_libdir)/qt4
		install_root=${D}/usr
		djconsole=0
		djconsole_legacy=0
		optimize=0
		hifieq=1
		ipod=0
		vinylcontrol=1"

	use debug && mysconsargs+=" qdebug=1" || mysconsargs+=" qdebug=0"
	use debug && mysconsargs+=" cmetrics=1" || mysconsargs+=" cmetrics=0"
}

src_prepare() {
	# patch external libsoundtouch && qt4 compatibility
	epatch ${FILESDIR}/${P}.patch

	# fix issues with cflags
	local flags="-Wall -W"
	use debug && flags="${flags} -g"
	sed -i  -e "s:-pipe -Wall -W -g:${flags}:" \
		src/SConscript || die "sed failed"

	# another cflags issue
	sed -i	-e 's:-O3::g' \
		lib/cmetrics/SConscript || die

	# Patch startup command if not using pulse audio
	use pulseaudio || sed -i -e 's:pasuspender ::' src/mixxx.desktop

	#Export paths for SConscript 
	export CCFLAGS=${CFLAGS}
	export CXXFLAGS=""
	export LINKFLAGS=${LDFLAGS}
	export LIBPATH=$(get_libdir)
}

src_compile() {
	# chicanery to use the correct compiler
	local cxx=$(type -P $(tc-getCXX))
	mkdir -p "${T}/bin"
	ln -s "${cxx}" "${T}/bin/g++" && \
	export PATH="${T}/bin:${PATH}"

	scons ${MAKEOPTS} ${mysconsargs} || die
}

src_install() {
	scons ${MAKEOPTS} ${mysconsargs} install || die

	dodoc README*

	insinto /usr/share/doc/${PF}/pdf
	doins Mixxx-Manual.pdf
}