app-antivirus/clamav-unofficial-sigs/clamav-unofficial-sigs-3.7.ebuild

clamav-unofficial-sigs-3.7.ebuild (text/plain), 2.41 KB, created by steveb on 2010-03-14 21:42:39 UTC

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: Exp $

EAPI=2

inherit eutils

DESCRIPTION="ClamAV Unofficial Signature Databases Update"
HOMEPAGE="http://www.inetmsg.com/pub/"
SRC_URI="http://www.inetmsg.com/pub/${PN}-${PV}.tar.gz
	http://www.inetmsg.com/pub/archive/${PN}-${PV}.tar.gz"
LICENSE="as-is"
SLOT="0"
KEYWORDS="alpha amd64 hppa ia64 ppc ppc64 sparc x86 ~x86-fbsd"
IUSE="logrotate"
S="${WORKDIR}/${PN}-${PV}"

RDEPEND="net-misc/rsync
	net-misc/curl
	net-misc/socat
	app-arch/gzip
	sys-apps/grep
	sys-apps/coreutils
	sys-apps/gawk
	sys-apps/sed
	sys-apps/findutils
	sys-apps/diffutils
	net-dns/bind-tools
	app-crypt/gnupg
	>=app-antivirus/clamav-0.94"
DEPEND="${RDEPEND}
	logrotate? ( app-admin/logrotate )"

src_prepare() {
	# Prepare configuration to suit Gentoo layout
	sed -i	-e "s:^\(#*clamd_socket[\t ]*=[\t ]*['\"]\)[^'\"]*\(['\"].*\)$:\1/var/run/clamav/clamd.sock\2:g" \
		-e "s:^\(#*clamd_pid[\t ]*=[\t ]*['\"]\)[^'\"]*\(['\"].*\)$:\1/var/run/clamav/clamd.pid\2:g" \
		-e "s:^\(#*clam_dbs[\t ]*=[\t ]*['\"]\)[^'\"]*\(['\"].*\)$:\1/var/lib/clamav\2:g" \
		-e "s:^\(#*work_dir[\t ]*=[\t ]*['\"]\)[^'\"]*\(['\"].*\)$:\1/var/tmp/clamav-unofficial-dbs\2:g" \
		-e "s:^\(#*reload_opt[\t ]*=[\t ]*\)['\"]\{0,2\}[\t ]*$:\1\"rc-config restart clamd\":g" \
	clamav-unofficial-sigs.conf || die "Failed to upgrade configuration file"
}

src_install() {
	dobin clamav-unofficial-sigs.sh
	doman clamav-unofficial-sigs.8
	dodoc README CHANGELOG
	insinto /etc
	doins clamav-unofficial-sigs.conf
	if use logrotate; then
		insinto /etc/logrotate.d
		newins clamav-unofficial-sigs-logrotate clamav-unofficial-sigs
	fi
	diropts -m0755 -o clamav -g clamav
	dodir /var/tmp/clamav-unofficial-dbs
}

pkg_postinst() {
	local min=$(date +%S)
	elog "Edit the /etc/clamav-unofficial-sigs.conf file to suit your needs. Don't"
	elog "forgett to set user_configuration_complete=\"yes\" to enable ${PN}."
	elog
	elog "For details, please see the clamav-unofficial-sigs(8) manual page."
	elog
	elog "Remember to run /usr/bin/clamav-unofficial-sigs.sh regularly to keep the"
	elog "virus signatures up to date. Recommendet method is to use cron. See"
	elog "manpages for cron(8) and crontab(5) for more info."
	elog
	elog "An example contab entry, causing the update script to run at ${min#0}"
	elog "minutes past the hour:"
	elog
	elog "${min} * * * * root /usr/bin/clamav-unofficial-sigs.sh >/dev/null 2>&1"
}