ifc-7.1.036.ebuild

ifc-7.1.036.ebuild (text/plain), 3.35 KB, created by Derek Dolney on 2003-12-11 16:55:54 UTC

# Copyright 1999-2003 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit rpm

DESCRIPTION="Intel Fortran Compiler 7.1 for Linux"
#            Note: it works on non-Intel x86 processors.
HOMEPAGE="http://www.intel.com/software/products/compilers/flin/"
SRC_URI="l_fc_pc_${PV}.tar"

KEYWORDS="-* ~x86"
SLOT="0"
LICENSE="icc-7.0" # Effectively the same license as icc
IUSE=""

DEPEND=">=virtual/linux-sources-2.4
	>=sys-libs/glibc-2.2.4"

RDEPEND=">=virtual/linux-sources-2.4
	>=sys-libs/glibc-2.2.4"

RESTRICT="fetch"

S=${WORKDIR}

pkg_nofetch() {
	einfo "This version of ifc must be manually downloaded. Perform these steps"
	einfo "to get it:"
	einfo
	einfo "1. If you have not already obtained your free, non-time limited,"
	einfo "non-commercial personal use license key from Intel(R), read and"
	einfo "agree to the licensing information at"
	einfo "http://www.intel.com/software/products/compilers/flin/noncom.htm"
	einfo "and fill in your info to have one emailed to you."
	einfo
	einfo "2. Do not download the version suggested in the email. Instead,"
	einfo "create a user account with 40 minutes of free Intel(R) Premier"
	einfo "Support, as described in the email, at"
	einfo "http://www.intel.com/software/products/registrationcenter/index.htm"
	einfo
	einfo "3. Login to https://premier.intel.com and download l_fc_pc_${PV}.tar"
	einfo "from the \"File Downloads\" section and see that it gets into"
	einfo "/usr/portage/distfiles."
	einfo
	einfo "Remeber to log out from your support account as soon as possible so"
	einfo "you don't burn up all your minutes. Go ahead and log out while the"
	einfo "file is downloading."
	einfo
	einfo "If you find a version newer than ${PV}, submit a bug report."
	einfo
	einfo "Note: you may instead choose to emerge ifc-7.1.008, which only"
	einfo "requires step 1 above."
}

src_unpack() {
	unpack ${A}

	for x in intel-*.i386.rpm;
	do
		rpm_unpack ${x} || die "Failed to unpack rpms.";
	done

	# From UNTAG_CFG_FILES() in Intel's 'install' script:
	SD=${S}/opt/intel # Build DESTINATION
	RD=/opt/intel # Real DESTINATION
	for FILE in $(find $SD/compiler70/ia??/bin/ -regex '.*[ei][cf]p?c$\|.*cfg$\|.*pcl$\|.*vars[^/]*.c?sh$' 2>/dev/null)
	do
		sed s@\<INSTALLDIR\>@$RD@g ${FILE} > ${FILE}.abs
		mv -f ${FILE}.abs ${FILE}
		chmod 755 ${FILE}
	done

# replace tags with package id in special files (from UNTAG_SUPPORT() in Intel's 'install' script)
	eval `grep "^[ ]*COMBOPACKAGEID=" install`

	SUPPORTFILE=${SD}/compiler70/docs/fsupport
	sed s@\<INSTALLTIMECOMBOPACKAGEID\>@$COMBOPACKAGEID@g $SUPPORTFILE > $SUPPORTFILE.abs
	mv $SUPPORTFILE.abs $SUPPORTFILE
	chmod 644 $SUPPORTFILE

	SUPPORTFILE=${SD}/compiler70/docs/idbsupport
	sed s@\<INSTALLTIMECOMBOPACKAGEID\>@$COMBOPACKAGEID@g $SUPPORTFILE > $SUPPORTFILE.abs
	mv $SUPPORTFILE.abs $SUPPORTFILE
	chmod 644 $SUPPORTFILE
}

src_install () {
	mv -f opt ${D}

	insinto /etc/env.d
	doins ${FILESDIR}/${PVR}/05icc-ifc

	# fix the issue with the primary ifc executable
	exeinto /opt/intel/compiler70/ia32/bin
	doexe ${FILESDIR}/${PVR}/ifc
}

pkg_postinst() {
	einfo "You will need to place the license file from your email in"
	einfo "/opt/intel/licenses/"
	einfo
	einfo "Note that if you are upgrading from an older version you do not need"
	einfo "a new license."
	einfo
	einfo "Documentation for the compiler can be found in"
	einfo "/opt/intel/compiler70/docs/"
}