net-analyzer/nikto/nikto-2.1.1.ebuild

nikto-2.1.1.ebuild (text/plain), 1.29 KB, created by David Abbott (RETIRED) on 2010-02-18 21:36:44 UTC

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=2

inherit eutils

DESCRIPTION="Web Server vulnerability scanner."
HOMEPAGE="http://www.cirt.net/code/nikto.shtml"
SRC_URI="http://www.cirt.net/source/nikto/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="ssl"

RDEPEND="dev-lang/perl
		net-analyzer/nmap
		ssl? (
			dev-libs/openssl
			dev-perl/Net-SSLeay
		)
		>=net-libs/libwhisker-2.5"

DEPEND="${RDEPEND}"

src_prepare() {
	rm docs/._* || die "removing osx files failes"
	epatch "${FILESDIR}"/${PN}.conf.patch || die "patch failes"
}

src_install() {

	dodir /etc/nikto || die "dodir failed"
	insinto /etc/nikto
	doins "${FILESDIR}/nikto.conf" || die "doins failed"

	dobin nikto.pl || die "dobin failed"
	dosym /usr/bin/nikto.pl /usr/bin/nikto || die "dobin failed"

	dodir /usr/share/nikto || die "dodir failed"
	insinto /usr/share/nikto
	doins -r docs || die "doins failed"

	dodir /var/lib/nikto || die "dodir failed"
	insinto /var/lib/nikto
	doins -r templates plugins || die "doins failed"

	dodoc docs/*.txt || die "dodoc failed"
	dohtml docs/nikto_manual.html || die "dohtml failed"
	doman docs/nikto.1 || die "doman failed"
}

pkg_postinst() {
	elog 'Default configuration file is "/etc/nikto/nikto.conf"'
}