Ebuild against [e-mail]-20091006145647-kqkmoh481tl5hvt4

be-9999.ebuild (text/plain), 1.23 KB, created by W. Trevor King on 2010-02-07 15:40:25 UTC

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="2"

inherit eutils

if [[ ${PV} == "9999" ]] ; then
	EBZR_REPO_URI="http://bzr.bugseverywhere.org/${PN}"
	inherit bzr
	SRC_URI=""
else
	SRC_URI="http://bugseverywhere.org/${PN}/${P}.tar.gz"
fi

DESCRIPTION="Bugs Everywere distributed bug tracker"
HOMEPAGE="http://bugseverywhere.org/"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="x86"
IUSE=""

RDEPEND="dev-lang/python
	dev-python/pyyaml"
DEPEND="${RDEPEND}
	dev-util/bzr
	app-text/docbook-sgml-utils"

src_unpack() {
	if [[ ${PV} == "9999" ]] ; then
		bzr_src_unpack
	else
		unpack ${A}
	fi
	cd "${S}"
	epatch ${FILESDIR}/${P}-install-dir.patch
	epatch ${FILESDIR}/${P}-version.patch
	epatch ${FILESDIR}/${P}-docbook2man.patch
}

if [[ ${PV} == "9999" ]] ; then
	src_prepare() {
		bzr_src_prepare || die
		EBZR_BRANCH_DIR="${EBZR_STORE_DIR}/${EBZR_CACHE_DIR}"
		bzr version-info --format python "${EBZR_BRANCH_DIR}" > \
			"${S}/libbe/_version.py" \
			|| die "Unable to make _verison.py from ${EBZR_BRANCH_DIR}"
	}
fi

src_compile() {
	emake || die
}

src_install() {
	emake DESTDIR="${D}" install || die
	dodoc AUTHORS NEWS README
	if [[ ${PV} != "9999" ]] ; then
		dodoc ChangeLog
	fi
}