cross-helper-1.15.3.ebuild

cross-helper-1.15.3.ebuild (text/plain), 2.76 KB, created by Peter Levine on 2010-01-28 06:22:31 UTC

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header:

inherit eutils flag-o-matic toolchain-funcs

DESCRIPTION="A minimal Busybox for native manipulation of a cross-compiled system"
HOMEPAGE="http://www.busybox.net/"
SRC_URI="http://www.busybox.net/downloads/busybox-${PV}.tar.bz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
IUSE=""
RESTRICT="test"

S="${WORKDIR}"/busybox-${PV}
busybox_config_option() {
	case $1 in
		y) sed -i -e "s:.*CONFIG_$2 .*set:CONFIG_$2=y:g" .config;;
		n) sed -i -e "s:CONFIG_$2=y:# CONFIG_$2 is not set:g" .config;;
		e) sed -i -e "s:.*CONFIG_$2=.*:CONFIG_$2=$3:g" .config;;
		*) use $1 \
		       && busybox_config_option y $2 \
		       || busybox_config_option n $2
		   return 0
		   ;;
	esac
	einfo $(grep "CONFIG_$2[= ]" .config || echo Could not find CONFIG_$2 ...)
}

src_unpack() {
	unset KBUILD_OUTPUT #88088

	unpack "${A}"
	cd "${S}"

	epatch "${FILESDIR}"/${PN}-portagecompat.patch

	# work around broken ass powerpc compilers
	use ppc64 && append-flags -mminimal-toc
	# flag cleanup
	sed -i -r \
		-e 's:[[:space:]]?-(Werror|Os|falign-(functions|jumps|loops|labels)=1|fomit-frame-pointer)\>::g' \
		Makefile.flags || die
	#sed -i '/bbsh/s:^//::' include/applets.h
	sed -i '/^#error Aborting compilation./d' applets/applets.c || die
	use elibc_glibc && sed -i 's:-Wl,--gc-sections::' Makefile
	sed -i \
		-e "/^CROSS_COMPILE/s:=.*:= ${CHOST}-:" \
		-e "/^HOSTCC/s:=.*:= $(tc-getBUILD_CC):" \
		Makefile || die

	# setup the config file
	emake -j1 allnoconfig > /dev/null

	local opt
	for opt in \
		STATIC NO_DEBUG_LIB INSTALL_APPLET_DONT \
		ASH_{BASH_COMPAT,OPTIMIZE_FOR_SIZE} PASSWD \
		USE_BB{_PWD_GRP,_SHADOW,_CRYPT_SHA} LONG_OPTS \
		USE_BB_CRYPT {ADD,DEL}{USER,GROUP} SHOW_USAGE
	do
		busybox_config_option y ${opt}
	done

	# PREFER_APPLETS & FEATURE_SH_STANDALONE
	# (and a shell) are needed so adduser execs
	# its own busybox commands and not from $PATH.
	for opt in \
		BUFFERS_USE_MALLOC ASSUME_UNICODE \
		SHADOWPASSWDS ADDUSER_TO_GROUP \
		DEL_USER_FROM_GROUP CHECK_NAMES \
		SH_{IS_ASH,STANDALONE} PREFER_APPLETS \
		VERBOSE_USAGE
	do
		busybox_config_option y FEATURE_${opt}
	done

	busybox_config_option n INSTALL_APPLET_SYMLINKS
	busybox_config_option n FEATURE_SH_IS_NONE

	# Needed for internal functions.
	busybox_config_option e BUSYBOX_EXEC_PATH \"/bin/${PN}\"
	
	# Set to shadow-utils defaults
	busybox_config_option e FIRST_SYSTEM_ID 101
	busybox_config_option e LAST_SYSTEM_ID 999

	emake -j1 oldconfig > /dev/null
}

src_compile() {
	unset KBUILD_OUTPUT #88088
	export SKIP_STRIP=y

	emake busybox || die "build failed"
}

src_install() {
	unset KBUILD_OUTPUT #88088

	into /
	newbin busybox_unstripped ${PN} || die
}