pyyim-t-9999.ebuild

pyyim-t-9999.ebuild (text/plain), 1.99 KB, created by Mike Becker on 2010-01-24 05:58:19 UTC

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

NEED_PYTHON=2.3

inherit eutils multilib python git

DESCRIPTION="Python based jabber transport for YIM"
HOMEPAGE="http://xmpppy.sourceforge.net/yahoo/"
EGIT_REPO_URI="git://github.com/normanr/yahoo-transport.git"
EGIT_BRANCH="master"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86 ~amd64"
IUSE=""
S=${WORKDIR}/${P}
DEPEND="net-im/jabber-base"
RDEPEND="${DEPEND}
        >=dev-python/imaging-1.1
        >=dev-python/twisted-2.2.0
        >=dev-python/twisted-words-0.1.0
        >=dev-python/twisted-web-0.5.0
        >=dev-python/xmpppy-0.4.1"


src_unpack() {
        git_src_unpack
}

src_install() {
        local inspath

        python_version
        inspath=/usr/$(get_libdir)/python${PYVER}/site-packages/${PN}
        insinto ${inspath}
        doins -r ${S}/curphoo
        doins ${S}/*.py

        insinto /etc/jabber
        newins ${S}/config_example.xml ${PN}.xml
        fperms 600 /etc/jabber/${PN}.xml
        fowners jabber:jabber /etc/jabber/${PN}.xml
        dosed \
                "s:<spooldir>[^\<]*</spooldir>:<spooldir>/var/spool/jabber</spooldir>:" \
                /etc/jabber/${PN}.xml
        dosed \
                "s:<pid>[^\<]*</pid>:<pid>/var/run/jabber/${PN}.pid</pid>:" \
                /etc/jabber/${PN}.xml
        dosym /etc/jabber/${PN}.xml /etc/pyyimt.conf.xml

        newinitd "${FILESDIR}/${PN}-${PV}-initd" ${PN}
        dosed "s:INSPATH:${inspath}:" /etc/init.d/${PN}
}

pkg_postinst() {
        python_version
        python_mod_optimize "${ROOT}usr/$(get_libdir)/python${PYVER}/site-packages/${PN}"

        elog "A sample configuration file has been installed in /etc/jabber/${PN}.xml."
        elog "Please edit it and the configuration of your Jabber server to match."
}

pkg_postrm() {
        python_version
        python_mod_cleanup "${ROOT}usr/$(get_libdir)/python${PYVER}/site-packages/${PN}"
}