Ebuild for the 0.702 version

tileracer-bin-0.702.ebuild (text/plain), 1.17 KB, created by Petr Zima on 2010-01-12 08:16:54 UTC

# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="2"

inherit games

MY_PN="TileRacer"

DESCRIPTION="3D stunt racing game"
HOMEPAGE="http://tileracer.model-view.com"
SRC_URI="${MY_PN}${PV}.tar.gz"
#RESTRICT="mirror"

LICENSE="blob"
SLOT="0"
KEYWORDS="~x86 ~amd64"
IUSE=""

DEPEND=""
RDEPEND="${DEPEND}"

S=${WORKDIR}

src_install() {
	dir=${GAMES_PREFIX_OPT}/${PN}
	reldir="release_linux"

	# install the shell script launcher
	exeinto "${dir}"
	doexe ${MY_PN}.sh || die "doexe (launcher) failed"

	# make symlink in GAMES_BINDIR
	dosym "${dir}"/${MY_PN}.sh "${GAMES_BINDIR}"/${PN} || die "dosym failed"

	# install the binary
	exeinto "${dir}"/${reldir}
	doexe ${reldir}/${MY_PN} || die "doexe (binary) failed"
	rm ${reldir}/${MY_PN}

	# install the rest files (i.e. libraries, configuration and data)
	insinto "${dir}"
	doins -r ${reldir} lib_linux media || die "doins failed"

	# install readme file
	dodoc README || die "dodoc failed"

	# install icon
	doicon ${MY_PN}128.png || die "doicon failed"

	# make desktop entry
	make_desktop_entry ${PN} "Tile Racer" ${MY_PN}128.png

	# check game permissions
	prepgamesdirs
}