drizzle-2009.12.1251-r1.ebuild

drizzle-2009.12.1251-r1.ebuild (text/plain), 5.01 KB, created by Francesco Riosa on 2009-12-26 00:15:32 UTC

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header$
# kate: encoding utf-8; eol unix
# kate: indent-width 4; mixedindent off; replace-tabs off; remove-trailing-space on; space-indent off
# kate: word-wrap-column 80; word-wrap off

EAPI=2

inherit flag-o-matic libtool autotools eutils

KEYWORDS="~amd64"

DESCRIPTION="A Microkernel DBMS for High Performance Scale-Out Applications"
HOMEPAGE="http://drizzle.org/"
DRIZZLE_RELEASE="bell"
SRC_URI="mirror://launchpad/drizzle/trunk/${DRIZZLE_RELEASE}/+download/drizzle-${PV}.tar.gz"
LICENSE="GPL"
SLOT="0"

IUSE_DRIZZLED_PLUGINS="+plugin-archive
              +plugin-ascii
              plugin-auth-http
              plugin-auth-pam
              +plugin-benchmark
              +plugin-blackhole
              +plugin-charlength
              +plugin-compression
              +plugin-connection-id
              +plugin-console
              +plugin-crc32
              +plugin-csv
              +plugin-default-replicator
              +plugin-drizzle-protocol
              +plugin-errmsg-stderr
              +plugin-filtered-replicator
              +plugin-gearman-udf
              +plugin-memory
              +plugin-hello-world
              +plugin-info-schema
              +plugin-information-engine
              +plugin-innobase
              +plugin-length
              plugin-logging-gearman
              plugin-logging-query
              plugin-logging-syslog
              +plugin-md5
              +plugin-memcached-functions
              +plugin-memcached-stats
              +plugin-multi-thread
              +plugin-myisam
              +plugin-mysql-protocol
              +plugin-pool-of-threads
              +plugin-show-schema-proto
              +plugin-signal-handler
              +plugin-single-thread
              +plugin-sleep
              +plugin-transaction-log
              +plugin-version"

# managed via normal USE flags
for i in "md5" "auth-http" "auth-pam"; do
	IUSE_DRIZZLED_PLUGINS="${IUSE_DRIZZLED_PLUGINS/?plugin-${i}/}"
done

# we don't want cruft on by default
IUSE_DRIZZLED_PLUGINS="${IUSE_DRIZZLED_PLUGINS/+plugin-hello-world/plugin-hello-world}"

# don't add an ssl USE flag here, since it's not ssl support that
# we're to use, but rather MD5 support
IUSE="debug tcmalloc doc memcache curl pam gearman gnutls openssl ${IUSE_DRIZZLED_PLUGINS}"

# upstream bug #499911
RESTRICT="memcache? ( test ) !curl? ( test )"

RDEPEND="tcmalloc? ( dev-util/google-perftools )
		dev-db/libdrizzle
		sys-libs/readline
		sys-apps/util-linux
		dev-libs/libpcre
		dev-libs/libevent
		dev-libs/protobuf
		gearman? ( sys-cluster/gearmand )
		pam? ( sys-libs/pam )
		curl? ( net-misc/curl )
		gnutls? ( net-libs/gnutls )
		memcache? ( dev-libs/libmemcached )"
DEPEND="${RDEPEND}
		dev-util/gperf
		doc? ( app-doc/doxygen )"
RDEPEND="${RDEPEND}
		curl? (
			gnutls? ( net-misc/curl[-openssl,-nss] )
			openssl? ( net-misc/curl[-gnutls,-nss] )
		)"

pkg_setup() {
	elog "This is a work-in-progress ebuild, some features will require"
	elog "manual configuration and others aren't fleshed out just yet."
	elog "Use it at your risk."

	if use gnutls && use openssl; then
		eerror "You cannot use both GnuTLS and OpenSSL at the same time"
		eerror "to provide the MD5 plugin. Please choose only one USE flag"
		eerror "between gnutls and openssl."
		die "Both gnutls and openssl USE flags enabled."
	fi
}

src_prepare() {
	epatch "${FILESDIR}/${PN}-2009.12.1240-asneeded.patch"
	epatch "${FILESDIR}/${PN}-2009.12.1240-nolint.patch"

	# disable hello_world tests as we don't care about the
	# demonstrative plugin.
	# https://bugs.launchpad.net/drizzle/+bug/499944
	rm "${S}"/tests/{t,r}/hello_world.* || die

	AT_M4DIR="m4" eautoreconf

	elibtoolize
}

src_configure() {
	local myconf=

	if use debug; then
		append-flags -DDEBUG
	fi

	if use gnutls; then
		myconf="${myconf} --with-md5-plugin"
		export ac_cv_libcrypto=no
	elif use openssl; then
		myconf="${myconf} --with-md5-plugin"
		export ac_cv_libgnutls_openssl=no
	else
		myconf="${myconf} --without-md5-plugin"
	fi

	for p in ${IUSE_DRIZZLED_PLUGINS}
	do
		myconf="${myconf} $(use_with ${p#+} ${p#*plugin-}-plugin)"
	done

	econf \
		--disable-rpath \
		--disable-static \
		--disable-dependency-tracking \
		--disable-mtmalloc \
		$(use_enable tcmalloc) \
		$(use_enable memcache libmemcached) \
		$(use_enable gearman libgearman) \
		$(use_with curl auth-http-plugin) \
		$(use_with pam auth-pam-plugin) \
		${myconf}
}

src_compile() {
	emake || die "build failed"

	if use doc; then
		emake doxygen || die "doxygen failed"
	fi
}

src_test() {
	# Explicitly allow parallel make check
	emake check || die "tests failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "install failed"
	dodoc AUTHORS NEWS README || die

	find "${D}" -name '*.la' -delete || die

	if use doc; then
		docinto apidoc
		pushd docs/html
		dohtml -r .
		popd
	fi
}

pkg_postinst() {
	if use pam; then
		ewarn "Be warned that we're still lacking a pam configuration"
		ewarn "file so the PAM authentication will not work by default"
	fi
}