update for building with current svn

vacuum-9999.ebuild (text/plain), 1.79 KB, created by Nikoli on 2009-12-07 23:11:49 UTC

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header:

EAPI="2"

inherit eutils qt4 subversion

ESVN_REPO_URI="http://vacuum-im.googlecode.com/svn/trunk"

DESCRIPTION="Qt4 Crossplatform Jabber client."
HOMEPAGE="http://code.google.com/p/vacuum-im"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
PLUGINS="+accountmanager adiummessagestyle +annotations +autostatus +avatars +bitsofbinary +bookmarks +captchaforms +chatmessagehandler +chatstates +clientinfo +commands +compress +connectionmanager +console +dataforms +datastreamsmanager +defaultconnection +emoticons +filestreamsmanager +filetransfer +gateways +inbandstreams +iqauth +jabbersearch +mainwindow +messagearchiver +messagestyles +messagewidgets +multiuserchat +normalmessagehandler +notifications +presence +privacylists +privatestorage +registration +roster +rosterchanger +rostersearch +rostersmodel +rostersview +saslauth +servicediscovery +sessionnegotiation +settings +simplemessagestyle +skinmanager +socksstreams +starttls +statuschanger +statusicons +traymanager +vcard +xmppstreams +xmppuriqueries"
IUSE="${PLUGINS}"

DEPEND=">=x11-libs/qt-gui-4.5:4
	adiummessagestyle? ( >=x11-libs/qt-webkit-4.5:4 )"
RDEPEND="${DEPEND}"
PDEPEND=""

src_configure() {
	sed -i -e '/INSTALL_PREFIX/s/\/local//' src/config.inc
	for plugin in ${PLUGINS//+/}
	do
		if ! use ${plugin}; then
			rm -rf {resources,src/plugins,translations/*}/${plugin}{,s}{,.qm}
			sed -e "s/${plugin}//" -i src/plugins/plugins.pro
		fi
	done
}

src_compile() {
	eqmake4 vacuum.pro
	emake || die "emake failed"
}

src_install() {
	emake INSTALL_ROOT="${D}" install || die "emake install failed"

	newicon resources/menuicons/shared/mainwindowlogo128.png ${PN}.png
	make_desktop_entry ${PN} "Vacuum IM" ${PN} "Qt;Network;InstantMessaging;"
}