sope-999999.ebuild

sope-999999.ebuild (text/plain), 8.20 KB, created by steveb on 2009-12-04 10:37:13 UTC

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=2

# gnustep-2 is pulling way to many dependencies.
inherit gnustep-base

if [ "${PV}" = "999999" ]; then
	ESVN_REPO_URI="http://svn.opengroupware.org/SOPE/trunk"
	inherit subversion
	use sogo && RDEPEND="${RDEPEND} dev-util/monotone"
	SRC_URI=""
	KEYWORDS=""
else
	MY_PV="1660-200908051100"
	SRC_URI="http://download.opengroupware.org/nightly/sources/trunk/${PN}-trunk-r${MY_PV}.tar.gz
		sogo? ( http://www.scalableogo.org/files/downloads/SOGo/Sources/SOGo-1.1.0.tar.gz )"
	KEYWORDS="~alpha amd64 ppc ~ppc64 ~sparc x86 ~x86-fbsd"
fi

DESCRIPTION="An extensive set of frameworks which form a complete Web application server environment"
HOMEPAGE="http://sope.opengroupware.org/en/index.html"
LICENSE="LGPL-2"
SLOT="0"
# No Apache2 dependency! The trunk does not build mod_ngobjweb.
# I could enable it but I did not wanted to fiddle more around
# with patching SOPE.
IUSE="ldap libFoundation mysql postgres sqlite sogo"
DEPEND="gnustep-base/gnustep-base
	dev-libs/libxml2
	dev-libs/openssl
	ldap? ( net-nds/openldap )
	mysql? ( virtual/mysql )
	postgres? ( virtual/postgresql-base )
	sqlite? ( >=dev-db/sqlite-3.0 )"
RDEPEND="${RDEPEND}
	${DEPEND}"
S=${WORKDIR}/${PN}

pkg_setup() {
	egnustep_env
	gnustep-base_pkg_setup
	local myLDFLAGS="$(gnustep-config --variable=LDFLAGS 2>/dev/null)"
	if [ -n "${myLDFLAGS}" ]; then
		ewarn
		ewarn "You seem to have compiled GNUstep with custom LDFLAGS. SOPE is very"
		ewarn "sensitive regarding custom LDFLAGS. If your SOPE install does not"
		ewarn "work as expected then please re-emerge SOPE and your GNUstep (base and"
		ewarn "make) without any LDFLAGS before filing bugs."
		ewarn
		ebeep 5
		epause 10
	fi
}

src_unpack() {
	if [ "${PV}" = "999999" ]; then
		subversion_src_unpack

		# SOGo Monotone
		EMTN_STORE_DIR="${PORTAGE_ACTUAL_DISTDIR:-${DISTDIR}}/mtn-src"
		addread "${EMTN_STORE_DIR}"
		addwrite "${EMTN_STORE_DIR}"
		if [ ! -d "${EMTN_STORE_DIR}" ]; then
			mkdir -p "${EMTN_STORE_DIR}" || die "Can't mkdir ${EMTN_STORE_DIR}."
		fi
		cd "${EMTN_STORE_DIR}" || die "Can't chdir to ${EMTN_STORE_DIR}"

		if [ ! -f "db.mtn" ]; then
			mtn db init --db=./db.mtn || die "Failed to initialize Monotone database"
		fi

		# Pull Inverse's SOGo Monotone repository
		mtn --db=./db.mtn pull inverse.ca ca.inverse.sogo || die "Failed to pull Monotone repository"
		if [ ! -d "SOGo" ]; then
			mtn --db=./db.mtn checkout --branch ca.inverse.sogo SOGo || die "Failed to checkout SOGo branch"
		else
			cd SOGo
			mtn update
		fi
	else
		unpack ${A}
	fi

	cd "${S}" || die "Change directory failed"
	if ! use sogo ; then
		epatch "${FILESDIR}"/${PN}-r1660-use_system_root.patch
		epatch "${FILESDIR}"/${PN}-r1660-configure.patch
		epatch "${FILESDIR}"/${PN}-r1660-NGImap4Client.patch
		[ "${PV}" != "999999" ] && epatch "${FILESDIR}"/${PN}-r1660-NSZoneMallocAtomic.patch
		epatch "${FILESDIR}"/${PN}-r1660-MySQL4Channel.m.patch
		epatch "${FILESDIR}"/${PN}-r1660-SoOFS.patch
		epatch "${FILESDIR}"/${PN}-r1660-destdir.patch
	else
		if [ "${PV}" = "999999" ]; then
			# http://www.scalableogo.org/english/support/faq/article/how-do-i-compile-sogo.html
			epatch "${EMTN_STORE_DIR}"/SOGo/SOPE/sope-gsmake2.diff
			epatch "${EMTN_STORE_DIR}"/SOGo/SOPE/sope-patchset-r*.diff
			#epatch "${EMTN_STORE_DIR}"/SOGo/SOPE/sope-ngobjweb-fix.diff
		else
			# http://www.scalableogo.org/english/support/faq/article/how-do-i-compile-sogo.html
			epatch "${WORKDIR}"/SOGo/SOPE/sope-gsmake2.diff
			epatch "${WORKDIR}"/SOGo/SOPE/sope-patchset-r*.diff
			#epatch "${WORKDIR}"/SOGo/SOPE/sope-ngobjweb-fix.diff
		fi
		epatch "${FILESDIR}"/${PN}-r1660-use_system_root.patch
		epatch "${FILESDIR}"/${PN}-r1660-SOGo-fix.patch
		[ "${PV}" != "999999" ] && epatch "${FILESDIR}"/${PN}-r1660-NSZoneMallocAtomic.patch
		epatch "${FILESDIR}"/${PN}-r1660-SoOFS.patch
		epatch "${FILESDIR}"/${PN}-r1660-MySQL4Channel.m.patch
		epatch "${FILESDIR}"/${PN}-r1660-NGLogSyslogAppender.m.patch
		epatch "${FILESDIR}"/${PN}-r1660-NGHttp+WO.m.patch
		#epatch "${FILESDIR}"/${PN}-r1660-WORepetition.m.patch
		#epatch "${FILESDIR}"/${PN}-r1660-NSDictionary+KVC.patch
		#epatch "${FILESDIR}"/${PN}-r1660-NSNull+misc.m.patch
	fi
	gnustep-base_src_prepare
}

src_configure() {
	cd "${S}"
	unset LDFLAGS
	egnustep_env
	local myconf
	if use libFoundation; then
		myconf="${myconf} --frameworks=libFoundation"
		local myCFLAGS="${CFLAGS}"
		cd "${S}"/libFoundation
		CFLAGS="${CFLAGS} -Wno-import" ./configure \
			--prefix=/usr \
			$(use_enable debug) \
			--with-gnustep || die "configure libFoundation failed"
		CFLAGS="${myCFLAGS}"
	fi
	cd "${S}"
	./configure \
		$(use_enable debug) \
		$(use_enable debug strip) \
		--with-gnustep ${myconf} || die "configure failed"
}

src_compile() {
	cd "${S}"
	unset LDFLAGS
	egnustep_env
	if use libFoundation; then
		cd "${S}"/libFoundation
		egnustep_make
	fi
	cd "${S}"
	egnustep_make

	# SOPE tends to break horribly if gnustep-make is build with LDFLAGS such as
	# -Wl,--add-needed or -Wl,--as-needed. So we check here some vital binaries.
	# Check if SoCore, SoOFS is correctly build/linked
	local mySoCoreLDD=$(ldd -d "${S}"/sope-appserver/NGObjWeb/SoCore.sxp/SoCore 2>&1 | grep "lib\(NG\(ObjWeb\|Mime\|Streams\|Extensions\)\|EOControl\|DOM\|SaxObjC\|XmlRpc\)\.so\." | wc -l)
	local mySoOFSLDD=$(ldd -d "${S}"/sope-appserver/SoOFS/SoOFS.sxp/SoOFS 2>&1 | grep "lib\(SoOFS\|NG\(ObjWeb\|Mime\|Streams\|Extensions\)\|EOControl\|DOM\|SaxObjC\|XmlRpc\)\.so\." | wc -l)
	if [ -z "${mySoCoreLDD}" -o -z "${mySoOFSLDD}" -o "${mySoCoreLDD}" != "8" -o "${mySoOFSLDD}" != "9" ]; then
		ewarn
		ewarn "This SOPE installtion is not correctly build. Probably you are using"
		ewarn "LDFLAGS to build SOPE that are not correctly handled in SOPE or you"
		ewarn "have emerged gnustep-base/gnustep-make with LDFLAGS which are"
		ewarn "preventing SOPE to link the needed libraries into it's own binaries."
		ewarn "Please remerge gnustep-base/gnustep-make and/or SOPE with empty LDFLAGS."
		ewarn
		die "SOPE build is not complete (SoCore, SoOFS)"
	fi
	# Do the same for WEExtensions, WOExtensions, WEPrototype
	local myWEExtensionsLDD=$(ldd -d "${S}"/sope-appserver/WEExtensions/WEExtensions.wox/WEExtensions 2>&1 | grep "lib\(WEExtensions\|NG\(ObjWeb\|Mime\|Streams\|Extensions\)\|EOControl\|DOM\|SaxObjC\|XmlRpc\)\.so\." | wc -l)
	local myWOExtensionsLDD=$(ldd -d "${S}"/sope-appserver/WOExtensions/WOExtensions.wox/WOExtensions 2>&1 | grep "lib\(W[EO]Extensions\|NG\(ObjWeb\|Mime\|Streams\|Extensions\)\|EOControl\|DOM\|SaxObjC\|XmlRpc\)\.so\." | wc -l)
	local myWEPrototypeLDD=$(ldd -d "${S}"/sope-appserver/WEPrototype/WEPrototype.wox/WEPrototype 2>&1 | grep "lib\(WEPrototype\|NG\(ObjWeb\|Mime\|Streams\|Extensions\)\|EOControl\|DOM\|SaxObjC\|XmlRpc\)\.so\." | wc -l)
	if [ -z "${myWEExtensionsLDD}" -o -z "${myWOExtensionsLDD}" -o -z "${myWEPrototypeLDD}" -o "${myWEExtensionsLDD}" != "9" -o "${myWOExtensionsLDD}" != "10" -o "${myWEPrototypeLDD}" != "9" ]; then
		ewarn
		ewarn "This SOPE installtion is not correctly build. Probably you are using"
		ewarn "LDFLAGS to build SOPE that are not correctly handled in SOPE or you"
		ewarn "have emerged gnustep-base/gnustep-make with LDFLAGS which are"
		ewarn "preventing SOPE to link the needed libraries into it's own binaries."
		ewarn "Please remerge gnustep-base/gnustep-make and/or SOPE with empty LDFLAGS."
		ewarn
		die "SOPE build is not complete (WEExtensions, WOExtensions, WEPrototype)"
	fi
}

src_install() {
	unset LDFLAGS
	newenvd "${FILESDIR}"/sope.envd 99sope \
		|| die "Failed installing env.d script"
	if ! use sogo ; then
		egnustep_env
		# I know, I know. GNUSTEP_INSTALLATION_DIR is deprecated. But SOPE
		# is no way a reference. It is full of issues and would require a
		# hell lot of patching to be considered as clean. Maybe newer
		# versions of SOPE will be better? (check out gsmake2 from their
		# svn if you want to see a cleaner edition of SOPE. But that one
		# requires as well some patching in order to be build on Gentoo)
		egnustep_install GNUSTEP_INSTALLATION_DIR="${D}/usr/GNUstep/System"
		use doc && egnustep_doc
		egnustep_install_config
	else
		gnustep-base_src_install
	fi
}

pkg_postinst() {
	gnustep-base_pkg_postinst
	elog
	elog "You need to update your path by running now:"
	elog "  /usr/sbin/env-update && source /etc/profile"
}