proposed ebuild

kpgen-1.2_beta2.ebuild (text/plain), 1.08 KB, created by Dror Levin (RETIRED) on 2009-11-16 17:29:32 UTC

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="2"

inherit qt4

MY_P="${PN}-src-${PV/_beta/b}-20090619173518"

DESCRIPTION="Strong password generator based on mouse movements"
HOMEPAGE="http://sourceforge.net/projects/kpgen/"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.bz2"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug"

DEPEND="x11-libs/qt-gui:4
	dev-libs/crypto++"
RDEPEND="${DEPEND}"

S="${WORKDIR}/${PN}"

src_configure() {
	cd "${S}/src"
	eqmake4
	lrelease "${PN}.pro"
}

src_compile() {
	cd "${S}/src"
	emake \
		TRANSLATION_PATH="\"\\\"/usr/share/${PN}/translations\\\"\"" \
		DOC_PATH="\"\\\"/usr/share/doc/${PF}\\\"\"" \
		KPGEN_BUILDNUMBER="$(cat ${S}/gitversion)" \
		KPGEN_VERSION="\"\\\"${PV/_/ }\\\"\"" \
		KPGEN_CUSTOM_VERSION='"\"Gentoo\""' || die "emake failed"
}

src_install() {
	emake \
		DESTDIR="${D}" \
		PREFIX="/usr" \
		TRANSLATION_PATH="/usr/share/${PN}/translations" \
		DOC_PATH="/usr/share/doc/${PF}" \
		install || die "install failed"

	dodoc README.txt Changelog.txt || die
}