media-gfx/pixie-2.2.6

pixie-2.2.6.ebuild (text/plain), 2.15 KB, created by MT on 2009-09-23 18:49:19 UTC

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="2"
inherit eutils multilib autotools

MY_PN="Pixie"
S="${WORKDIR}/${MY_PN}"

DESCRIPTION="RenderMan like photorealistic renderer."
HOMEPAGE="http://pixie.sourceforge.net"
SRC_URI="mirror://sourceforge/${PN}/${MY_PN}-src-${PV}.tgz"

LICENSE="GPL-2"
IUSE="X static-libs"
SLOT="0"
KEYWORDS="amd64 ~ppc sparc x86"

RDEPEND="!mail-client/nmh
	media-libs/jpeg
	media-libs/tiff
	media-libs/libpng
	x11-libs/fltk:1.1[opengl]
	media-libs/openexr
	virtual/opengl
	X? (
		x11-libs/libXext
		x11-libs/libICE
		x11-libs/libSM
		x11-libs/libX11
		x11-libs/libXau
		x11-libs/libxcb
		x11-libs/libXdmcp
		x11-libs/libXi
		x11-libs/libXmu
		x11-libs/libXt
	)"
DEPEND="${RDEPEND}
	sys-libs/zlib
	sys-devel/flex
	sys-devel/bison"

src_prepare() {
#	# Force make to rebuild the shaders since the packaged ones
#	# are not always compiled with the latest version of sdr
#	epatch "${FILESDIR}/${P}-shaders.patch"
#	rm "${S}"/shaders/*.sdr

	# FIX: missing @includedir@
	epatch "${FILESDIR}/${P}-autotools.patch"
	eautoreconf
}

src_configure() {
	econf \
		$(use_with X x) \
		$(use_enable static-libs static) \
		--includedir=/usr/include/pixie \
		--libdir=/usr/$(get_libdir)/pixie \
		--with-docdir=/usr/share/doc/${P}/html \
		--with-shaderdir=/usr/share/Pixie/shaders \
		--with-ribdir=/usr/share/Pixie/ribs \
		--with-texturedir=/usr/share/Pixie/textures \
		--with-displaysdir=/usr/$(get_libdir)/pixie/displays \
		--with-modulesdir=/usr/$(get_libdir)/pixie/modules \
		--enable-openexr-threads \
		--mandir=/usr/share/man \
		--bindir=/usr/bin \
		|| die "econf failed"
}

src_install() {
	make DESTDIR="${D}" install || die

	# remove useless .la files
	if ! use static-libs; then
		for LA_FILE in "${D}"/usr/$(get_libdir)/${PN}/lib{ri,sdr,pixiecommon}.la; do
			rm ${LA_FILE} || die "rm ${LA_FILE} file failed"
		done
		rm "${D}"/usr/lib/pixie/modules/gui.la || die "rm gui.la file failed"
		for LA_FILE in "${D}"/usr/$(get_libdir)/${PN}/displays/{rgbe,openexr,framebuffer,file}.la; do
			rm ${LA_FILE} || die "rm ${LA_FILE} file failed"
		done
	fi

	dodoc {README,AUTHORS,ChangeLog}
}