www-client/google-chrome-bin-4.0.203.2-r24690.ebuild

google-chrome-bin-4.0.203.2-r24690.ebuild (text/plain), 3.42 KB, created by Daniel Lin on 2009-08-29 21:10:26 UTC

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="2"

inherit eutils toolchain-funcs versionator

MY_PN="${PN%-bin}-unstable"
MY_P="${MY_PN}_${PVR}"
SRC_BASE="http://dl.google.com/linux/deb/pool/main/${MY_PN:0:1}/${MY_PN}/"

DESCRIPTION="Google Chrome is a browser that combines a minimal design with sophisticated technology to make the web faster, safer, and easier."
HOMEPAGE="http://www.google.com/chrome"
SRC_URI="x86? ( ${SRC_BASE}${MY_P}_i386.deb )
	amd64? ( ${SRC_BASE}${MY_P}_amd64.deb )"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~x86 ~amd64"
IUSE=""

RESTRICT="primaryuri"

DEPEND="app-arch/lzma-utils !~app-arch/deb2targz-1"
RDEPEND="|| ( media-fonts/liberation-fonts media-fonts/corefonts )
	media-libs/alsa-lib
	>=dev-libs/atk-1.13.2
	>=sys-libs/glibc-2.6
	>=x11-libs/cairo-1.4.0
	>=media-libs/fontconfig-2.4.0
	>=media-libs/freetype-2.3.5
	>=dev-libs/glib-2.14.0:2
	>=x11-libs/gtk+-2.12.0:2
	>=dev-libs/nspr-4.7.1
	>=dev-libs/nss-3.12.3
	>=x11-libs/pango-1.18.3
	>=sys-devel/gcc-4.2.1[-nocxx]
	>=x11-misc/xdg-utils-1.0.1
	>=sys-libs/zlib-1.2.3"

CHROME_HOME="opt/google/chrome"

QA_PRESTRIPPED="
	${CHROME_HOME}/chrome
	${CHROME_HOME}/chrome-sandbox
	${CHROME_HOME}/libavcodec.so.52
	${CHROME_HOME}/libavformat.so.52
	${CHROME_HOME}/libavutil.so.50"
# Ogg/Theora/Vorbis-only FFmpeg binaries
QA_TEXTRELS="
	${CHROME_HOME}/libavcodec.so.52
	${CHROME_HOME}/libavformat.so.52
	${CHROME_HOME}/libavutil.so.50"
QA_EXECSTACK="opt/google/chrome/chrome"

pkg_nofetch() {
	elog "Please download"
	for i in ${A}; do
		[[ ${i} = ${MY_PN}_* ]] && elog "${SRC_BASE}${i}"
	done
	elog "and save to ${DISTDIR}"
}

src_unpack() {
	for i in ${A}; do
		unpack ${i}
		if [[ ${i} = *.deb ]]; then
			if [[ -e ${WORKDIR}/data.tar.lzma ]]; then
				mv ${WORKDIR}/data.tar.lzma ${WORKDIR}/${i%%_*}.tar.lzma
			elif [[ -e ${WORKDIR}/data.tar.gz ]]; then
				mv ${WORKDIR}/data.tar.gz ${WORKDIR}/${i%%_*}.tar.gz
			else
				die "Can't find data from ${i}"
			fi
		fi
	done
}

src_install() {
	cd "${D}"

	lzma -cd ${WORKDIR}/${MY_PN}.tar.lzma | tar xvf - || die "Couldn't extract"
	rm -r etc usr/bin/google-chrome

	for i in nss/lib{nss{,util},smime,ssl}3.so.1d \
		     nspr/lib{pl{ds,c},nspr}4.so.0d; do
		dosym ../../../../usr/$(get_libdir)/${i%.*} \
			/${CHROME_HOME}/${i##*/}
	done

	cat <<-EOF >"${T}/google-chrome"
		#!/bin/sh
		exec /${CHROME_HOME}/google-chrome --enable-plugins \
		--enable-greasemonkey --enable-user-scripts --enable-extensions \
		"\$@"
	EOF
	dobin "${T}/google-chrome"

	sed "s:Exec=/.*/:Exec=:" \
		${CHROME_HOME}/google-chrome.desktop > "${T}/google-chrome.desktop"
	insinto /usr/share/applications
	doins "${T}/google-chrome.desktop"

	dosym /usr/$(get_libdir)/nsbrowser/plugins /${CHROME_HOME}/plugins
}

pkg_postinst() {
	elog "This Chrome binary package is from the developer preview channel.  It is"
	elog "not guaranteed to be stable or even usable."
	elog ""
	elog "Chrome's auto-update mechanism is only available for Debian-based"
	elog "distributions, and has been disabled."
	elog ""
	elog "Please see"
	elog "    http://dev.chromium.org/for-testers/bug-reporting-guidlines-for-the-mac-linux-builds"
	elog "before filing any bugs."
	if ! version_is_at_least 4.2 "$(gcc-version)" || [[ -z $(tc-getCXX) ]]; then
		einfo ""
		ewarn "This Chrome binary package depends on C++ libraries from >=sys-devel/gcc-4.2,"
		ewarn "which do not appear to be available.  Google Chrome may not run."
		ebeep
	fi
}