net-misc/netkit-telnet-ssl-0.17.24.ebuild

netkit-telnet-ssl-0.17.24.ebuild (text/plain), 2.28 KB, created by Daniel Lin on 2009-08-21 19:54:45 UTC

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils toolchain-funcs

EXTRAVERSION=0.1
PATCHLEVEL=22
DESCRIPTION="Standard Linux telnet client and server with SSL support"
HOMEPAGE="ftp://ftp.uk.linux.org/pub/linux/Networking/netkit/"
# http://packages.debian.org/unstable/source/netkit-telnet-ssl
MY_PV="${PV}${EXTRAVERSION:++${EXTRAVERSION}}"
MY_PVR="${MY_PV}-${PATCHLEVEL}"
SRC_URI="mirror://debian/pool/main/${PN:0:1}/${PN}/${PN}_${MY_PV}.orig.tar.gz
	mirror://debian/pool/main/${PN:0:1}/${PN}/${PN}_${MY_PVR}.diff.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
IUSE=""

DEPEND=">=sys-libs/ncurses-5.2
	>=dev-libs/openssl-0.9.8g
	!net-misc/telnet-bsd
	!net-misc/netkit-telnetd"

S="${WORKDIR}/${PN}-${MY_PV}.orig"

src_unpack() {
	unpack ${A}
	cd "${S}"
	# Patch: [0]
	# Gentoo lacks a maintainer for this package right now. And a
	# security problem arose. While reviewing our options for how
	# should we proceed with the security bug we decided it would be
	# better to just stay in sync with debian's own netkit-telnet
	# package. Lots of bug fixes by them over time which were not in
	# our telnetd.
	epatch "${WORKDIR}/${PN}_${MY_PVR}.diff"

	# Patch: [1]
	# after the deb patch we need to add a small patch that defines
	# gnu source. This is needed for gcc-3.4.x (needs to be pushed
	# back to the deb folk?)
	epatch "${FILESDIR}"/netkit-telnet-ssl-0.17-cflags-gnu_source.patch
}

src_compile() {
	./configure --prefix=/usr || die

	sed -i \
		-e "s:-pipe -O2:${CFLAGS}:" \
		-e "s:^\(LDFLAGS=\).*:\1${LDFLAGS}:" \
		-e "s:-Wpointer-arith::" \
		-e "s:^CC=.*:CC=$(tc-getCC):" \
		-e "s:^CXX=.*:CXX=$(tc-getCXX):" \
		MCONFIG

	make || die
	cd telnetlogin && make || die
}

src_install() {
	dobin telnet/telnet || die

	dosbin telnetd/telnetd || die
	dosym telnetd /usr/sbin/in.telnetd
	dosbin telnetlogin/telnetlogin || die
	doman telnet/telnet.1
	doman telnetd/*.8
	doman telnetd/issue.net.5
	dosym telnetd.8 /usr/share/man/man8/in.telnetd.8
	doman telnetlogin/telnetlogin.8
	dodoc BUGS ChangeLog README
	dodoc "${FILESDIR}"/net.issue.sample
	newdoc telnet/README README.telnet
	newdoc telnet/TODO TODO.telnet
	insinto /etc/xinetd.d
	newins "${FILESDIR}"/telnetd.xinetd telnetd
}