ebuild for jana2000

jana2000-20071218.ebuild (text/plain), 1.53 KB, created by Hannes Krüger on 2009-07-09 20:28:04 UTC

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header:$

inherit eutils fortran toolchain-funcs

DESCRIPTION="the crystallographic computing system"
HOMEPAGE="http://www-xray.fzu.cz/jana/jana.html"
SRC_URI="ftp://ftp.fzu.cz/pub/cryst/beta2000/${PN}.tar.gz"

FORTRAN="g77 gfortran"

LICENSE="freedist"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

RDEPEND="x11-libs/libX11"
DEPEND="${RDEPEND}
	x11-proto/xproto
	sys-apps/gawk"

S="${WORKDIR}/${PN}"

src_unpack() {
	unpack ${A}
	cd "${S}"

	einfo "setting up the Makefile for ${FORTRANC}"

	if [[ ${FORTRANC} == gfortran ]]; then
		epatch "${FILESDIR}/${PV}-gfortran.diff"
	elif [[ ${FORTRANC} == g77 ]]; then
		epatch "${FILESDIR}/${PV}-g77.diff"
	fi
}

src_compile() {
	emake -j1 CCOM="$(tc-getCC)" || die "emake failed"
}

src_install() {
	dobin jana2000 || die "dobin failed"
	dodoc README.TXT || die "dodoc failed"

	insinto /usr/share/${PN}/source
	doins -r source/{fg,data} || die "doins failed"

	echo "JANADIR=/usr/share/${PN}" >"${T}/jana2000env"
	newenvd "${T}/jana2000env" 99jana2000env || die "newenvd failed"
}

pkg_postinst() {
	echo
	elog "The Development of Jana2000 is stopped." 
	elog "The successor Jana2006 is not yet available for unix/linux platforms"
	elog "check at http://www-xray.fzu.cz/jana/jana.html for news"
	elog "please cite Jana2000 as follows:"
	elog "  Petricek, V., Dusek, M. and Palatinus, L. (2000):"
	elog "  Jana2006. The crystallographic computing system."
	elog "  Institute of Physics, Praha, Czech Republic."
	echo
}