updated ebuild

velocity-dvsl-1.0.ebuild (text/plain), 1.41 KB, created by Ralph Sennhauser (RETIRED) on 2009-03-27 10:28:53 UTC

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="2"
JAVA_PKG_IUSE="doc examples source test"

inherit java-pkg-2 java-ant-2

DESCRIPTION="Declarative Velocity Style Language."
HOMEPAGE="http://velocity.apache.org/dvsl/devel/"
SRC_URI="mirror://apache/velocity/dvsl/${PV}/${P}-src.zip"

LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~amd64"

COMMON_DEP="
	dev-java/ant-core:0
	dev-java/dom4j:1
	dev-java/velocity:0"
RDEPEND="
	>=virtual/jre-1.5
	${COMMON_DEP}"
DEPEND="
	>=virtual/jdk-1.5
	app-arch/unzip
	test? (
		dev-java/commons-collections:0
		dev-java/commons-lang:2.1
		dev-java/jaxen:1.1
		dev-java/junit:4
	)
	${COMMON_DEP}"

S="${WORKDIR}/${P}-src"
EANT_DOC_TARGET="javadocs"

src_unpack() {
	unpack ${A}

	mkdir "${S}/lib"
	cd "${S}/lib" || die
	java-pkg_jar-from ant-core
	java-pkg_jar-from dom4j-1
	java-pkg_jar-from velocity

	sed -i -e 's/depends="static,download"/depends="static"/' \
		"${S}/build.xml" || die
}

src_test () {
	cd "${S}/lib" || die
	java-pkg_jar-from --build-only commons-collections
	java-pkg_jar-from --build-only commons-lang-2.1
	java-pkg_jar-from --build-only jaxen-1.1
	java-pkg_jar-from --build-only junit-4

	cd "${S}"
	eant test
}

src_install() {
	java-pkg_newjar "dist/${P}.jar" "${PN}.jar"
	use doc && java-pkg_dojavadoc target/javadoc
	use examples && java-pkg_doexamples examples/*
	use source && java-pkg_dosrc src/java/*
}