jde-2.3.6_pre20081208.ebuild

jde-2.3.6_pre20081208.ebuild (text/plain), 1.74 KB, created by Ulrich Müller on 2009-03-10 12:22:08 UTC

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

WANT_ANT_TASKS="ant-nodeps"
JAVA_PKG_IUSE="doc source"

inherit java-pkg-2 java-ant-2 elisp eutils

DESCRIPTION="Java Development Environment for Emacs"
HOMEPAGE="http://jdee.sourceforge.net/"
SRC_URI="http://dev.gentoo.org/~ulm/distfiles/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

RDEPEND=">=virtual/jdk-1.3
	app-emacs/elib
	>=app-emacs/cedet-1.0_beta3
	dev-java/bsh
	=dev-java/junit-3*"
DEPEND="${RDEPEND}
	dev-util/checkstyle"

S="${WORKDIR}/${PN}"
SITEFILE="70${PN}-gentoo.el"

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}/${P}-import.patch"

	cd java/lib || die
	java-pkg_jar-from --build-only checkstyle checkstyle.jar checkstyle-all.jar
	java-pkg_jar-from junit
	java-pkg_jar-from bsh
}

src_compile() {
	eant dist \
		-Dcedet.dir="${SITELISP}/cedet" \
		-Delib.dir="${SITELISP}/elib"

	#cd dist/java/lib/ || die
	#rm checkstyle-all.jar
	#java-pkg_jar-from junit
	#java-pkg_jar-from bsh
}

src_install() {
	# Java
	java-pkg_dojar dist/java/lib/jde.jar

	#jde.jar has direct dependencies on bsh.jar and junit.jar
	#it seems to bundle TestCases inside the jar so junit may
	#not actually be required, or maybe functionality depends
	#on it but code doesn't. No code deps exist for checkstyle
	#but again maybe functionality does? Lets not install it and see.

	use source && java-pkg_dosrc java/src/*
	use doc && java-pkg_dojavadoc dist/doc/java/api

	# Lisp
	elisp-install ${PN} build/lisp/*.{el,elc} || die
	elisp-site-file-install "${FILESDIR}/${SITEFILE}" || die

	# Bin
	dobin lisp/jtags || die

	# Documentation
	dohtml -r dist/doc/html/* || die
	dodoc lisp/readme.txt lisp/ChangeLog lisp/ReleaseNotes.txt
}