pks-0.9.6.ebuild - cleaned up version

pks-0.9.6.ebuild (text/plain), 1.90 KB, created by Petre Rodan on 2009-03-07 06:26:57 UTC

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: Exp $

inherit eutils

DESCRIPTION="The OpenPGP Public Key Server"
HOMEPAGE="http://pks.sourceforge.net"
SRC_URI="mirror://sourceforge/pks/${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="amd64 x86"
IUSE=""

DEPEND=""
RDEPEND=""

LOCALESTATEDIR=/var/lib/pks

pkg_setup() {
	enewgroup pks
	enewuser pks -1 -1 /var/lib/pks pks
}

src_compile() {
	econf --localstatedir=${LOCALESTATEDIR} --datadir=/usr/share/${P} || die
	emake || die
}

src_install() {
	dosbin pksd
	dobin \
	  db2-sleepycat/dist/db_archive \
	  db2-sleepycat/dist/db_checkpoint \
	  db2-sleepycat/dist/db_deadlock \
	  db2-sleepycat/dist/db_dump \
	  db2-sleepycat/dist/db_load \
	  db2-sleepycat/dist/db_printlog \
	  db2-sleepycat/dist/db_recover \
	  db2-sleepycat/dist/db_stat \
	  pksclient \
	  pksdctl \
	  pgpsplit \
	  pks-mail.sh \
	  pks-queue-run.sh

	dodoc README UPGRADING NEWS ChangeLog

	doman *.5 *.8

	diropts -o"pks" -g"pks"
	dodir ${LOCALESTATEDIR}
	dodir ${LOCALESTATEDIR}/db

	diropts -o"nobody" -g"nobody"
	dodir ${LOCALESTATEDIR}/incoming

	insinto ${LOCALESTATEDIR}
	newins pks-commands.html index.html

	insinto /usr/share/${P}
	doins mail_intro pks_help.{cz,de,dk,en,es,fi,fr,hr,ja,kr,no,pl,pt,se,tw}

	insinto /etc
	newins pksd.conf pksd.conf

	exeinto /etc/init.d
	newexe "${FILESDIR}/pksd.init-${PV}" pksd
}

pkg_postinst () {
	einfo "If this is a new install, you should do the following"
	einfo "/usr/bin/pksclient ${LOCALESTATEDIR}/db create"
	einfo "${EDITOR} /etc/pksd.conf"
	einfo ""
	einfo "If you want to be able to synchronize with other keyserver then"
	einfo "setup your MTA and add the following lines to your aliases file "
	einfo ""
	einfo "pgp-public-keys: \"|/usr/bin/pks-mail.sh /etc/pksd.conf\""
	einfo "pgp: pgp-public-keys"
	einfo ""
	einfo "Check pks-intro(8) for the database administration informations"
}