Fixed parallel make, added USE=threads support, fixed repoman warnings

xharbour-1.0.0_beta1.ebuild (text/plain), 3.40 KB, created by Phil Krylov on 2009-03-04 18:39:47 UTC

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils

MY_P=${P/_/-}
DESCRIPTION="An extended implementation of the Clipper dialect of the xBase language family"
HOMEPAGE="http://www.xharbour.org/"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.src.tar.gz"

LICENSE="GPL-2-with-exceptions"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="allegro gpm odbc slang threads X"

RDEPEND="virtual/libc
	sys-libs/ncurses
	allegro? ( media-libs/allegro )
	gpm? ( sys-libs/gpm )
	odbc? ( dev-db/unixODBC )
	slang? ( sys-libs/slang )
	X? ( x11-libs/libX11
		 x11-libs/libXmu
		 x11-libs/libXext
		 x11-libs/libXt
		 x11-libs/libXpm
		 media-libs/freetype )"
DEPEND="${RDEPEND}
	sys-devel/bison"

S="${WORKDIR}/${MY_P}"

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/${PN}-parallel-make.patch || die
	epatch "${FILESDIR}"/${PN}-mkinstdir.patch || die
}

set_vars() {
	local HB_ARCH=$(uname -s | tr -d "[-]" | tr '[A-Z]' '[a-z]' 2>/dev/null)
	local HB_CPU HB_PIC
	case "${HB_ARCH}" in
		*bsd)
			HB_ARCH="bsd"
			;;
		linux)
			# Add -fPIC on amd64 to support building shared libraries from
			# static ones, as documented in part 3.g of this document:
			# http://www.gentoo.org/proj/en/base/amd64/howtos/index.xml?part=1&chap=3
			# Probably the upstream could fix it some fine day, but now they
			# prefer to save an extra build pass and build everything with
			# -fPIC.
			if [ "${CFLAGS}" == "${CFLAGS//-fPIC/}" ]
			then
				HB_CPU=$(uname -m)
				case "${HB_CPU}" in
					*[@_]64)
						HB_PIC="-fPIC"
						;;
				esac
			fi
			;;
	esac
	export \
		C_USR="${CFLAGS} ${HB_PIC}" \
		L_USR="${LDFLAGS}" \
		HB_GTALLEG=$(useq allegro && echo yes) \
		HB_GPM_MOUSE=$(useq gpm && echo yes) \
		HB_WITHOUT_GTSLN=$(useq slang || echo yes) \
		HB_MT=$(useq threads && echo MT) \
		HB_WITHOUT_X11=$(useq X || echo yes) \
		HB_COMPILER="gcc" \
		HB_ARCHITECTURE="${HB_ARCH}" \
		HB_GT_LIB="gtstd" \
		HB_MULTI_GT="yes" \
		HB_COMMERCE="no"
}

src_compile() {
	set_vars || die
	emake || die
}

src_test() {
	utils/hbtest/*/*/hbtest
	einfo "In general, the package works if 'Total calls passed' figure above"
	einfo "is 90% or greater."
}

src_install() {
	export _DEFAULT_BIN_DIR=/usr/bin
	export _DEFAULT_INC_DIR=/usr/include/xharbour
	export _DEFAULT_LIB_DIR=/usr/lib/xharbour
	export HB_BIN_INSTALL="${D}"/usr/bin
	export HB_INC_INSTALL="${D}"/usr/include/xharbour
	export HB_LIB_INSTALL="${D}"/usr/lib/xharbour
	set_vars || die
	emake install || die

	dodir /etc/harbour
	install -m644 source/rtl/gtcrs/hb-charmap.def "${D}"/etc/harbour/hb-charmap.def
	cat > "${D}"/etc/harbour.cfg <<EOF
CC=gcc
CFLAGS=-c -I${_DEFAULT_INC_DIR} ${CFLAGS}
VERBOSE=YES
DELTMP=YES
EOF

	# rebuild tools with shared libs
	unset HB_GTALLEG
	L_USR="${L_USR} -L${HB_LIB_INSTALL} -l${PN} -lncurses"
	use slang && L_USR="${L_USR} -lslang"
	use gpm && L_USR="${L_USR} -lgpm"
	use X && L_USR="${L_USR} -L/usr/X11R6/lib -lX11"
	export PRG_USR="\"-D_DEFAULT_INC_DIR='${_DEFAULT_INC_DIR}'\""
	for utl in hbmake hbrun hbpp xbscript
	do
		emake -C utils/${utl} clean || die
		emake -C utils/${utl} install || die
	done

	dosym xbscript /usr/bin/pprun
	dosym xbscript /usr/bin/xprompt

	# remove unused files
	rm -f "${HB_BIN_INSTALL}"/{hbdoc,hbtest,hbdict*.hit,gharbour,harbour-link}

	dodoc ChangeLog doc/*.txt || die
	docinto en
	dodoc doc/en/*.txt || die
	docinto es
	dodoc doc/es/*.txt || die
	docinto ct
	dodoc doc/en/ct/*.txt || die
}