kicad-20090220.1600.ebuild

kicad-20090220.1600.ebuild (text/plain), 1.76 KB, created by Bignaux Ronan on 2009-02-26 16:05:46 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit versionator wxwidgets cmake-utils

MY_PV="$(get_major_version)-r$(get_after_major_version)"

DESCRIPTION="Electronic Schematic and PCB design tools."
HOMEPAGE="http://kicad.sourceforge.net"
SRC_URI="http://beischer.com/kicad/kicad-source/${PN}-${MY_PV}-source.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="doc debug examples minimal python"

RDEPEND="sys-libs/zlib
	=x11-libs/wxGTK-2.8*
	python? ( dev-lang/python )"

DEPEND="${RDEPEND}
	dev-libs/boost
	>=dev-util/cmake-2.6.0
	!minimal? ( sci-electronics/kicad-library )
	doc? ( sci-electronics/kicad-doc )"


S="${WORKDIR}"

pkg_setup() {
	WX_GTK_VER="2.8"
	need-wxwidgets unicode
	check_wxuse opengl
}

src_unpack() {
    unpack ${A}
	cd "${S}"

	if ! use examples ; then
		sed -i -e "s:^add_subdirectory(demos):#add_subdirectory(demos):" \
		CMakeLists.txt || die "sed failed"
	fi
}

src_compile() {
	cmakeargs="-DKICAD_MINIZIP=OFF"

	if use python ; then
		cmakeargs+=" -DKICAD_PYTHON=ON"
	else
		cmakeargs+=" -DKICAD_PYTHON=OFF"
	fi

	cmake-utils_src_compile
}

pkg_postinst() {
	if use minimal ; then
		ewarn "If the schematic and/or board editors complain about missing libraries when you"
		ewarn "open old projects, you will have to take one or more of the following actions :"
		ewarn "- Install the missing libraries manually or emerge sci-electronics/kicad-library."
		ewarn "- Remove the libraries from the 'Libs and Dir' preferences."
		ewarn "- Fix the libraries' locations in the 'Libs and Dir' preferences."
		ewarn "- Emerge kicad without the 'minimal' USE flag."
	fi
	elog
	elog "You may want to emerge media-gfx/wings if you want to create 3D models of components."
}