x11-misc/zim/zim-0.27.ebuild

zim-0.27.ebuild (text/plain), 1.80 KB, created by Ilya Kashirin on 2008-11-27 07:39:55 UTC

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-misc/zim/zim-0.23.ebuild,v 1.1 2008/05/11 14:24:35 drac Exp $

EAPI=1

inherit fdo-mime perl-module

MY_P=${P/z/Z}

DESCRIPTION="A desktop wiki"
HOMEPAGE="http://www.zim-wiki.org"
SRC_URI="http://www.zim-wiki.org/downloads/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="latex screenshot spell"

DEPEND=">=dev-lang/perl-5.8
	>=x11-libs/gtk+-2.10
	virtual/perl-Storable
	virtual/perl-File-Spec
	>=dev-perl/File-BaseDir-0.03
	>=dev-perl/File-MimeInfo-0.12
	>=dev-perl/File-DesktopEntry-0.03
	>=dev-perl/gtk2-perl-1.040
	x11-misc/xdg-utils"

RDEPEND="${DEPEND}
	latex? ( virtual/latex-base app-text/dvipng )
	screenshot? ( media-gfx/scrot )
	spell? ( dev-perl/gtk2-spell )"

S="${WORKDIR}/${MY_P}"

PATCHES=( "${FILESDIR}/${PN}-0.27-disable-update-databases.patch" )

add_plugin() {
	name=$1

	sed -i -e "s/\(plugins=.*\)\$/\1,$name/" "${S}/share/zim/default.conf"
}

src_compile() {
	add_plugin TrayIcon
	use latex && add_plugin EquationEditor
	use screenshot && add_plugin InsertScreenshot
	use spell && add_plugin Spell

	perl-module_src_compile
}

pkg_postinst() {
	perl-module_pkg_postinst
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update
	einfo "Adding icon resource ..."
	xdg-icon-resource install --context mimetypes --size 64	"${ROOT}usr/share/pixmaps/zim.png" text-x-zim-notebook
}

pkg_postrm() {
	perl-module_pkg_postrm
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update

	# XXX: for up-/downgrades postinst is run first
	# thus we are then reverting the "xdg-icon-resource install" call and
	# nothing gets installed =/
	einfo "Removing icon resource ..."
	xdg-icon-resource uninstall --context mimetypes --size 64 text-x-zim-notebook
}