openarena-0.8.1.ebuild

openarena-0.8.1.ebuild (text/plain), 1.93 KB, created by Tomáš Chvátal (RETIRED) on 2008-11-02 00:47:05 UTC

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="1"

inherit games versionator

MY_PV=$(delete_all_version_separators)

DESCRIPTION="Open-source replacement for Quake 3 Arena"
HOMEPAGE="http://openarena.ws/"
SRC_URI="http://download.tuxfamily.org/openarena/rel/"${MY_PV}"/oa"${MY_PV}".zip
	http://openarena.ws/svn/source/"${MY_PV}"/"${PN}"-engine-"${PV}"-1.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="+curl dedicated +openal smp +vorbis"

RDEPEND="virtual/opengl
	media-libs/libsdl
	media-libs/speex
	x11-libs/libXext
	x11-libs/libX11
	x11-libs/libXau
	x11-libs/libXdmcp
	curl? ( net-misc/curl )
	openal? ( media-libs/openal )
	vorbis? ( media-libs/libvorbis )"
DEPEND="app-arch/unzip"

MY_S="${WORKDIR}"/"${PN}"-engine-"${PV}"
BUILD_DIR="${PN}-build"
DIR="${GAMES_DATADIR}/${PN}"

src_compile() {
	local myopts

	# use allways system speex and enable voip through it, disable mumble
	myopts="${myopts} USE_INTERNAL_SPEEX=0 USE_VOIP=1 USE_MUMBLE=0"
	use curl || myopts="${myopts} USE_CURL=0"
	use dedicated || myopts="${myopts} BUILD_SERVER=0"
	use openal || myopts="${myopts} USE_OPENAL=0"
	use smp && myopts="${myopts} BUILD_CLIENT_SMP=1"
	use vorbis || myopts="${myopts} USE_CODEC_VORBIS=0"

	cd "${MY_S}"
	emake \
		DEFAULT_BASEDIR="${DIR}" \
		BR="${BUILD_DIR}" \
		${myopts} \
		|| die "emake failed"
}

src_install() {
	local exe="openarena"

	use smp && exe="${exe}-smp"
	pushd "${MY_S}"/"${BUILD_DIR}"
	newgamesbin "${exe}".* "${PN}" || die "binary install failed"
	if use dedicated; then
		newgamesbin "${exe}"ded.* "${PN}-ded" || die "dedicated binary not found"
	fi
	popd

	insinto "${dir}"
	doins -r baseoa || die "doins -r failed"
	doins -r missionpack || die "doins -r failed"

	dodoc CHANGES CREDITS LINUXNOTES README || die "doc creation failed"
	newicon "${MY_S}"/misc/quake3.png "${PN}".png
	make_desktop_entry "${PN}" "OpenArena" "${PN}"

	prepgamesdirs
}