An ebuild integrating the patch

ebuild (text/plain), 1.45 KB, created by nixscripter on 2008-10-13 21:12:24 UTC

# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/lives/lives-0.9.1.ebuild,v 1.8 2007/11/27 14:14:27 zzam Exp $

inherit flag-o-matic eutils autotools

DESCRIPTION="Linux Video Editing System"

HOMEPAGE="http://www.xs4all.nl/~salsaman/lives"

MY_PN=LiVES
MY_P=${MY_PN}-${PV}

SRC_URI="mirror://sourceforge/lives/${MY_P}-src.tar.bz2"

LICENSE="GPL-2"

SLOT="0"

KEYWORDS="~amd64 ~ppc x86"

IUSE="matroska ogg theora libvisual"

DEPEND=">=media-video/mplayer-0.90-r2
		>=media-gfx/imagemagick-5.5.6
		>=dev-lang/perl-5.8.0-r12
		>=x11-libs/gtk+-2.2.1
		media-libs/libsdl
		>=media-video/ffmpeg-0.4.8
		>=media-libs/jpeg-6b-r3
		>=media-sound/sox-12.17.3-r3
		virtual/cdrtools
		theora? ( media-libs/libtheora )
		>=dev-lang/python-2.3.4
		matroska? ( media-video/mkvtoolnix
					media-libs/libmatroska )
		ogg? ( media-sound/ogmtools )
		>=media-video/mjpegtools-1.6.2
		libvisual? ( =media-libs/libvisual-0.2* )"

S=${WORKDIR}/${MY_P}

#
# Applies patch to fix hang during install in response to bug #153410
#
src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/fix-hangs.patch
	eautoreconf || die "eautoreconf failed"
}

src_compile() {
	use amd64 && append-flags -fPIC -DPIC
	econf \
		$(use_enable libvisual) || die "configure failed"
	emake || die "make failed"
}

src_install() {
	make DESTDIR="${D}" install || die
	dodoc AUTHORS CHANGELOG FEATURES GETTING.STARTED
}