gromacs-3.3.3.ebuild

gromacs-3.3.3.ebuild (text/plain), 5.79 KB, created by Alexey Shvetsov on 2008-05-29 15:03:13 UTC

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/gromacs/gromacs-3.3.1.ebuild,v 1.1 2006/08/08 02:54:41 markusle Exp $

inherit eutils fortran

IUSE="X 3dnow altivec mpi xml double-precision +single-precision sse sse2 static fortran blas lapack"

# mopac7 qm/mm is broken until we can get files from
# http://md.chem.rug.nl/~groenhof/qmmm.html
# or somewhere else...

DESCRIPTION="The ultimate molecular dynamics simulation package"
SRC_URI="ftp://ftp.gromacs.org/pub/${PN}/${P}.tar.gz"
HOMEPAGE="http://www.gromacs.org/"

EAPI="1"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~x86 ~amd64 ~ppc64 ~sparc"

# gromacs uses fortran intrinsics such as RSHIFT that
# are currently missing from gfortran; hence we need
# to require g77 for the time being (see bug #141672).
FORTRAN="g77 gfortran"


#mpi is a local USE flag now
#May become official when situation with mpich is cleared (now the only mpi implementation awailable is lam-mpi)
DEPEND=">=sci-libs/fftw-3.0.1
		mpi? ( virtual/mpi )
		>=sys-devel/binutils-2.15
		app-shells/tcsh
		X? ( x11-libs/libX11
			x11-libs/libXt
			x11-libs/libXp
			x11-libs/libXext
			x11-proto/xproto
			virtual/motif )
		xml? ( dev-libs/libxml2 )
		blas? ( virtual/blas )
		lapack? ( virtual/lapack )"

pkg_setup() {
	if use fortran; then
		fortran_pkg_setup
	fi
}

src_unpack() {
	unpack ${A}
	if ( use ppc64 && use altivec ) ; then
		epatch "${FILESDIR}"/"${PN}"-ppc64-altivec.patch
	fi
	cd "${S}"

	# Fix typos in a couple of files.
	sed -e "s:+0f:-f:" -i share/tutor/gmxdemo/demo \
		|| die "Failed to fixup demo script."

	# Fix a sandbox violation that occurs when re-emerging with mpi.
	sed "/libdir=\"\$(libdir)\"/ a\ temp_libdir=\"${D}usr/$( get_libdir )\" ; \\\\" \
		-i src/tools/Makefile.am \
		|| die "sed tools/Makefile.am failed"

	sed -e "s:\$\$libdir:\$temp_libdir:" \
		-i src/tools/Makefile.am \
		|| die "sed tools/Makefile.am failed"

	# some things for people who wants both versions of gromacs single and double precision
	cd "${WORKDIR}"
	if ( use double-precision && use single-precision ) ; then
	    einfo "Moving sources for Multiprecision Build"
		cp -pR "${P}" "${P}-single"
	    cp -pR "${P}" "${P}-double"
		rm -rf "${P}"
	fi
}

src_compile() {
	# static should work but something's broken.
	# gcc spec file may be screwed up.
	# Static linking should try -lgcc instead of -lgcc_s.
	# For more info:
	# http://lists.debian.org/debian-gcc/2002/debian-gcc-200201/msg00150.html
	local myconf ;

	case "${ARCH}" in

		x86)
			if ( use sse || use sse2 ) ; then
				myconf="${myconf} --enable-ia32-sse"
			fi
			if use 3dnow ; then
				myconf="${myconf} --enable-ia32-3dnow"
			fi
			# If you don't enable at least one of the above, you must use g77, not gfortran.
			if ( ! use sse && ! use sse2 && ! use 3dnow ) ; then
				if ! has_version "=sys-devel/gcc-3*" ; then
					die "If you must run gromacs without sse (not recommended) gfortran will not work."
				else myconf="${myconf} --enable-fortran" && fortran_pkg_setup
				fi
			fi
		;;

		amd64)
			myconf="${myconf} --enable-x86-64-sse"
		;;

		ppc)
			if use altivec ; then
				myconf="${myconf} --enable-ppc-altivec --disable-fortran"
			else
				if ! has_version "=sys-devel/gcc-3*" ; then
					die "If you must run gromacs without altivec (not recommended) gfortran will not work."
				fi
				myconf="${myconf} --enable-fortran" && fortran_pkg_setup
			fi
		;;

		ppc64)
			if use altivec ; then
				myconf="${myconf} --enable-ppc-altivec --disable-fortran"
			else
				if ! has_version "=sys-devel/gcc-3*" ; then
					die "If you must run gromacs without altivec (not recommended) gfortran will not work."
				fi
				myconf="${myconf} --enable-fortran" && fortran_pkg_setup
			fi
		;;

		sparc)
			if ! has_version "=sys-devel/gcc-3*" ; then
				die "If you must run gromacs without sse (not recommended) gfortran will not work."
			else
				myconf="${myconf} --enable-fortran" && fortran_pkg_setup
			fi
		;;

		ia64)
			myconf="${myconf} --enable-ia64-asm"
		;;

		alpha)
			myconf="${myconf} --enable-axp-asm --disable-fortran"
		;;

	esac
	# if we need external blas
	if use blas; then
		export LIBS="${LIBS} -lblas"
		myconf="${myconf} $(use_with blas external-blas)"
	fi
	# if we need external lapack
	if use lapack; then
		export LIBS="${LIBS} -llapack"
		myconf="${myconf} $(use_with lapack external-lapack)"
	fi

	myconf="${myconf} $(use_with xml) $(use_enable mpi) $(use_with X x) $(use_enable static all-static)"

	if ( use double-precision && use single-precision ); then
		einfo "Building Single Precison Gromacs"
	    cd "${WORKDIR}"/"${P}"-single
	    econf ${myconf} $(use_enable single-precision float) \
			|| die "Single Precision econf failed"
	    emake || die "Single Precision emake failed"
		einfo "Building Double Precision Gromacs"
	    cd "${WORKDIR}"/"${P}"-double
	    econf ${myconf} $(use_enable double-precision double) \
			|| die "Double Precision econf failed"
	    emake || die "Double Precision emake failed"
	else
		einfo "Building..."
	    cd "${WORKDIR}"/"${P}"
	    econf ${myconf} $(use_enable double-precision double) $(use_enable	single-precision float) --program-suffix= \
			|| die "Configure failed"
		emake || die "make failed"
	fi

}

src_install() {
	if ( use double-precision && use single-precision ); then
	    einfo "Installing Single Precision"
		cd "${WORKDIR}"/"${P}"-single
	    make DESTDIR="${D}" install || die
		einfo "Installing Double Precision"
	    cd "${WORKDIR}"/"${P}"-double
	    make DESTDIR="${D}" install || die
	else
		einfo "Installing..."
	    cd "${WORKDIR}"/"${P}"
	    make DESTDIR="${D}" install || die
	fi
	# Install documentation.
	dodoc AUTHORS INSTALL README

	#move html docs under /usr/share/doc
	#and leave examples and templates under /usr/gromacs...
	mv "${D}"/usr/share/"${PN}"/html "${D}"/usr/share/doc/"${PF}"/
}