media-sound/transkode-0.7.ebuild

transkode-0.7.ebuild (text/plain), 1.85 KB, created by Jure Kobal on 2008-05-02 20:05:29 UTC

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

ARTS_REQUIRED="never"

inherit kde

S="${WORKDIR}/${PN}"

DESCRIPTION="KDE frontend for various audio transcoding tools"
HOMEPAGE="http://kde-apps.org/content/show.php?content=37669"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"

LICENSE="GPL-2"

SLOT="0"
KEYWORDS="~amd64 ~x86"

IUSE="amarok ffmpeg gstreamer mplayer wavpack xine"

RDEPEND="media-libs/taglib
	amarok? ( media-sound/amarok )
	ffmpeg? ( media-video/ffmpeg )
	gstreamer? (
			>=media-libs/gstreamer-0.10
			>=media-libs/gst-plugins-good-0.10
			>=media-plugins/gst-plugins-flac-0.10
			>=media-plugins/gst-plugins-lame-0.10
			>=media-plugins/gst-plugins-vorbis-0.10
			>=media-plugins/gst-plugins-ogg-0.10
			>=media-plugins/gst-plugins-faad-0.10
		)
	mplayer? ( media-video/mplayer )
	wavpack? ( media-sound/wavpack )
	xine? ( media-sound/xineadump )"

DEPEND="${RDEPEND}"

need-kde 3.5

pkg_setup() {
	if ! use ffmpeg || ! use mplayer || ! use gstreamer; then
		echo
		ewarn "transKode should be emerged with at least one of next"
		ewarn "use flags: mplayer, ffmpeg, gstreamer or xine!"
		ewarn "None of them is mandatory but installs programs that"
		ewarn "can be used for decoding of audio formats for which no "
		ewarn "other decoder is present."
		echo
		ebeep
		epause 10
	fi
}

src_compile() {
	local myconf="$(use_enable amarok amarokscript)"

	kde_src_compile
}

src_install() {
	kde_src_install

	dodir /usr/share/applications/kde
	mv "${D}/usr/share/applnk/${PN}.desktop" \
		"${D}/usr/share/applications/kde"
}

pkg_postinst() {
	if use amarok; then
		elog "If you want to use TransKode to encode audio files on the fly"
		elog "when transferring music to a portable media device, remember"
		elog "to start the TransKode script through the Script Manager"
		elog "on the Tools menu."
	fi
}