modified ebuild

sndpeek-1.3.ebuild (text/plain), 1.77 KB, created by Olivier Huber on 2008-04-05 08:26:43 UTC

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/sndpeek/sndpeek-1.3.ebuild,v 1.1 2008/03/30 00:30:05 cedk Exp $

inherit eutils toolchain-funcs

DESCRIPTION="real-time audio visualization"
HOMEPAGE="http://soundlab.cs.princeton.edu/software/sndpeek/"
SRC_URI="http://soundlab.cs.princeton.edu/software/${PN}/files/${P}.tgz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE="oss jack alsa"

DEPEND="virtual/glut
	virtual/opengl
	virtual/glu
	x11-libs/libXmu
	x11-libs/libX11
	x11-libs/libXext
	jack? ( media-sound/jack-audio-connection-kit )
	alsa? ( media-libs/alsa-lib )"
RDEPEND="${DEPEND}"

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}/${P}-makefile.patch"
	epatch "${FILESDIR}/makefile.jack.patch"
}

pkg_setup() {
	local cnt=0
	use jack && cnt="$((${cnt} + 1))"
	use alsa && cnt="$((${cnt} + 1))"
	use oss && cnt="$((${cnt} + 1))"
	if [[ "${cnt}" -eq 0 ]]; then
		eerror "One of the following USE flags is needed: jack, alsa or oss"
		die "Please set one audio engine type"
	elif [[ "${cnt}" -ne 1 ]]; then
		ewarn "You have set ${P} to use multiple audio engine."
	fi
}

src_compile() {
	cd "${S}/src/sndpeek"

	local backend
	if use jack; then
	compil_backend jack
	fi

	if use alsa; then
	compil_backend alsa
	fi

	if use oss; then
	compil_backend oss
	fi
}

src_install() {

	if use jack; then
	dobin src/sndpeek/sndpeek-jack
	fi

	if use alsa; then
	dobin src/sndpeek/sndpeek-alsa
	fi

	if use oss; then
	dobin src/sndpeek/sndpeek-oss
	fi

	dodoc AUTHORS README THANKS TODO VERSIONS
}

compil_backend() {
	backend=$1
	einfo "Compiling against ${backend}"
	emake -f "makefile.${backend}" CC=$(tc-getCC) CXX=$(tc-getCXX) || die "emake failed"
	mv sndpeek sndpeek-${backend}
	emake clean

}