gtkradiant-1.5.0_p20080401.ebuild

gtkradiant-1.5.0_p20080401.ebuild (text/plain), 4.26 KB, created by James Le Cuirot on 2008-04-02 09:56:20 UTC

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit subversion eutils games flag-o-matic

DESCRIPTION="Level editor for BSP-based games"
HOMEPAGE="http://www.qeradiant.com"
SRC_URI="mirror://gentoo/Q3Pack.tar.bz2"
LICENSE="BSD GPL LGPL"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug doc"

RDEPEND="app-crypt/mhash
	dev-libs/libxml2
	media-libs/libpng
	sys-libs/zlib
	x11-libs/gtkglext
	=x11-libs/gtk+-2*"

DEPEND="${RDEPEND}
	dev-util/scons"

ESVN_REPO_URI='https://zerowing.idsoftware.com/svn/radiant/GtkRadiant/trunk'
ESVN_PATCHES="${P%%_p*}-browser.patch ${P%%_p*}-text-color.patch ${P%%_p*}-flags.patch"
ESVN_REVISION='237'

GP_REPO_URI='https://zerowing.idsoftware.com/svn/radiant.gamepacks'
GP_PROJECT='radiant-gamepacks/radiant.gamepacks'
GP_REVISION='33'

checkout_directory() {
	local parent=`dirname "$1"`
	[[ "${parent}" != "." ]] && checkout_directory "${parent}"

	ESVN_PROJECT="${GP_PROJECT}/${parent}" ESVN_RESTRICT='export' ESVN_OFFLINE=1 ESVN_OPTIONS='-N' subversion_fetch "${GP_REPO_URI}/${1}"
}

src_unpack() {
	subversion_src_unpack
	mkdir -p games

	local dir game offline
	unset ESVN_REVISION

	ESVN_PROJECT="${GP_PROJECT%%/*}" ESVN_RESTRICT='export' ESVN_OFFLINE=1 ESVN_OPTIONS='-N' subversion_fetch "${GP_REPO_URI}"

	for dir in 'DarkPlaces' 'Doom3 /tools' 'ET' 'HalfLife' 'Her2' 'JA /Tools' 'JK2' 'Nexuiz' 'Q1' 'Q2' 'Q4 /tools' 'STVEF' 'Sof2' 'Tremulous /tools' 'UFOAI' 'Warsow /tools' 'Wolf /bin' ; do
		set -- ${dir}
		set "$1Pack" "$2"

		mkdir -p "${S}/games/$1$2"
		checkout_directory "$1/trunk$2"

		ESVN_PROJECT="${GP_PROJECT}/$1/trunk$2"
		ESVN_REVISION="${GP_REVISION}" subversion_fetch "${GP_REPO_URI}/$1/trunk$2/games" "games/$1$2/games"

		for game in "${ESVN_STORE_DIR}/${ESVN_PROJECT}/games"/*.game ; do
			[[ "${game##*/}" == "hlcs.game" ]] && continue # Missing directory?
			ESVN_REVISION="${GP_REVISION}" subversion_fetch "${GP_REPO_URI}/$1/trunk$2/${game##*/}" "games/$1$2/${game##*/}"
		done
	done
	
	# Files for this game are missing from the repository.
	checkout_directory "Q3Pack/trunk"
	tar jxf "${DISTDIR}/Q3Pack.tar.bz2" -C "${S}/games" || die

	if use doc ; then
		# The Radiant manual is kept in the gamepack repository.
		checkout_directory "Q3Rad_Manual"	
		ESVN_PROJECT="${GP_PROJECT}/Q3Rad_Manual" ESVN_REVISION="${GP_REVISION}" subversion_fetch "${GP_REPO_URI}/Q3Rad_Manual/trunk" "install/Q3Rad_Manual"

		# These games have their docs in the wrong directory. Check out and move.
		for dir in 'ET' 'JA /Tools' 'JK2' 'Q3 /tools' 'STVEF' 'Sof2' 'Warsow /tools' 'Wolf /bin' ; do
			set -- ${dir}
			game=`echo $1 | tr A-Z a-z`
			ESVN_PROJECT="${GP_PROJECT}/$1Pack/trunk" ESVN_REVISION="${GP_REVISION}" subversion_fetch "${GP_REPO_URI}/$1Pack/trunk/docs" "games/$1Pack$2/${game}.game/docs"
		done
	else
		# These games already have their docs located within their game directories.
		rm -r "${S}/games/JAPack/Tools/ja.game/docs" "${S}/games/TremulousPack/tools/trem.game/docs"
	fi

	# Fix the paths for games that we have in Portage.
	for dir in 'DarkPlaces /usr/share/games/quake1' 'Doom3 /opt/doom3' 'ET /opt/enemy-territory' 'Her2 /opt/heretic2' 'Nexuiz /usr/share/games/quake1' 'Q1 /usr/share/games/quake1' 'Q2 /usr/share/games/quake2' \
			'Q3 /usr/share/games/quake3' 'Q4 /opt/quake4' 'Tremulous /usr/share/games/tremulous' 'UFOAI /usr/share/games/ufo-ai' 'Warsow /usr/share/games/warsow' 'Wolf /opt/rtcw' ; do
		set -- ${dir}
		find "${S}/games/$1Pack" -type f -path "*.game" -exec sed -i "s:enginepath_linux=\".*\":enginepath_linux=\"$2/\":" {} \;
	done

	# Missing directory?
	rm -f "${S}/games/HalfLifePack/games/hlcs.game"

	# Make Wolf's bspc executable. This file is prebuilt for x86 though.
	chmod 750 "${S}/games/WolfPack/bin/wolf.game/bspc"
}

src_compile() {
	local build='release'
	use debug && build='debug'

	# scons sucks.
	filter-ldflags -Wl,--as-needed

	scons ${MAKEOPTS} CCFLAGS="${CFLAGS}" CXXFLAGS="${CXXFLAGS}" \
		LINKFLAGS="${LDFLAGS}" BUILD="${build}" SETUP=0 || die
}

src_install() {
	local dir file

	mkdir -p ../msvc_redist # install.py assumes this exists.
	python ./install.py || die
	cd install || die

	dir="${GAMES_PREFIX_OPT}/${PN}"
	dodir "${dir}" || die
	cp -a * "${D}/${dir}" || die

	file=`ls radiant.* || die`
	dosym "${dir}/${file}" "${GAMES_BINDIR}/radiant" || die

	prepgamesdirs
}