conntrack-tools-0.9.6.ebuild

conntrack-tools-0.9.6.ebuild (text/plain), 1.45 KB, created by Peter Volkov (RETIRED) on 2008-03-19 07:32:07 UTC

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-firewall/conntrack-tools/conntrack-tools-0.9.5.ebuild,v 1.4 2008/03/09 22:46:31 swegener Exp $

inherit linux-info

DESCRIPTION="Connection tracking userspace tools"
HOMEPAGE="http://people.netfilter.org/pablo/conntrack-tools/"
SRC_URI="http://www.netfilter.org/projects/conntrack-tools/files/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~sparc ~x86"
IUSE=""

DEPEND=">=net-libs/libnfnetlink-0.0.33
	>=net-libs/libnetfilter_conntrack-0.0.89"
RDEPEND="${DEPEND}
	!net-firewall/conntrack"

pkg_setup() {
	linux-info_pkg_setup

	if kernel_is lt 2 6 18 ; then
		die "${PN} requires at least 2.6.18 kernel version"
	fi

	#netfilter core team has changed some option names with kernel 2.6.20
	if kernel_is lt 2 6 20 ; then
		CONFIG_CHECK="IP_NF_CONNTRACK_NETLINK CONFIG_NF_CONNTRACK_IPV4"
	else
		CONFIG_CHECK="NF_CT_NETLINK"
	fi

	check_extra_config
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	newinitd "${FILESDIR}/conntrackd.initd" conntrackd
	newconfd "${FILESDIR}/conntrackd.confd" conntrackd

	insinto /etc/conntrackd
	doins doc/stats/conntrackd.conf

	# INSTALL has some relevant information. Keep it here.
	dodoc AUTHORS ChangeLog INSTALL
	insinto /usr/share/doc/${PF}
	# Clean unnecessary .svn directories
	find "${S}" -type d -name ".svn" -print0 | xargs -0 -n1 rm -R
	doins -r doc
}