salome-pycalculator : change doc installation path

salome-pycalculator-3.2.6.ebuild (text/plain), 3.77 KB, created by François DORIN on 2008-02-22 17:12:37 UTC

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2


inherit autotools distutils eutils flag-o-matic toolchain-funcs versionator python multilib

DESCRIPTION="SALOME : The Open Source Integration Platform for Numerical Simulation. PYCALCULATOR Component"
HOMEPAGE="http://www.salome-platform.org"
SRC_URI="salome-3.2.6.tar.gz"

LICENSE="GPL-2"
KEYWORDS="~amd64 ~x86"
SLOT="0"
IUSE="doc opengl openpbs mpi debug"
RESTRICT="fetch"

RDEPEND="opengl? ( virtual/opengl )
         mpi? ( sys-cluster/mpich2 )
         openpbs? ( sys-cluster/torque )
         debug? ( dev-util/cppunit )"

DEPEND="${RDEPEND}
        >=sci-misc/salome-kernel-3.2.6
        dev-python/omniorbpy
        net-misc/omniORB"

# Note that Corba is apparently not optional in this module

MODULE_NAME="PYCALCULATOR"
MY_S="${WORKDIR}/src${PV}/${MODULE_NAME}_SRC_${PV}"
INSTALL_DIR="/opt/salome-${PV}/${MODULE_NAME}"
PYCALCULATOR_ROOT_DIR="/opt/salome-${PV}/${MODULE_NAME}"

export OPENPBS="/usr"

pkg_nofetch()
{
	einfo "You have to download manually the source code. You can download it from :"
	einfo "   http://www.salome-platform.org/download/dl326"
	einfo ""
	einfo "Put the archive in the \"/usr/portage/distfile\" directory and rename it \"salome-3.2.6.tar.gz\""
}


src_unpack()
{
	unpack ${A}
	cd ${MY_S}
	epatch ${FILESDIR}/salome-pycalculator-3.2.6.patch
}


src_compile()
{
	python_version

	cd "${MY_S}"
	rm -r -f autom4te.cache
	ewarn "The 'threads' flag MUST be ON and boost (at least) must be rebuild with this flag on"
	./build_configure

        # CXXFLAGS are slightly modified to allow the compilation of
        # salome-pycalculator with OpenCascade and gcc-4.1.x
        if version_is_at_least "4.1" $(gcc-version) ; then
                append-flags -ffriend-injection -fpermissive
        fi 

	# If vtk-5.O is used, include directory is named vtk-5.0 and not vtk
	if has_version ">=sci-libs/vtk-5.0"; then
	   einfo "vtk version 5 detected"
	   append-flags -I/usr/include/vtk-5.0
	else
	   einfo "vtk version 4 or prior detected";
	fi

	# Compiler and linker flags
        if use amd64 ; then
                append-flags -m64
        fi


	econf --prefix=${INSTALL_DIR} \
	      --datadir=${INSTALL_DIR}/share/salome \
	      --docdir=${INSTALL_DIR}/doc/salome \
	      --infodir=${INSTALL_DIR}/share/info \
	      --with-python-site=${INSTALL_DIR}/lib/python${PYVER}/site-packages/salome \
	      --libdir=${INSTALL_DIR}/$(get_libdir)/salome \
	      $(use_enable debug ) \
	      $(use_enable !debug production ) \
	      $(use_with debug cppunit /usr ) \
	      $(use_with opengl ) \
	      $(use_with openpbs ) \
	      $(use_with mpi mpich) \
	      || die "configuration failed"

	MAKEOPTS="-j1" emake || die "Compilation failed"
}


src_install()
{
	cd ${MY_S}
	emake prefix="${D}/${INSTALL_DIR}" \
	      docdir="${D}/${INSTALL_DIR}/doc/salome" \
	      infodir="${D}/${INSTALL_DIR}/share/info" \
	      datadir="${D}/${INSTALL_DIR}/share/salome" \
	      PYTHON_SITE_INSTALL="${D}/${INSTALL_DIR}/lib/python${PYVER}/site-packages/salome" \
	      sharedpydir="${D}/${INSTALL_DIR}/usr/lib/python${PYVER}/site-packages/salome/shared_modules" \
	      libdir="${D}/${INSTALL_DIR}/$(get_libdir)/salome" install \
	      || die "emake install failed"

        echo "${MODULE_NAME}_ROOT_DIR=${INSTALL_DIR}" > ./90${P}
        echo "LDPATH=${INSTALL_DIR}/$(get_libdir)/salome" >> ./90${P}
	echo "PATH=${INSTALL_DIR}/bin/salome" >> ./90${P}
	echo "PYTHONPATH=${INSTALL_DIR}/lib/python${PYVER}/site-packages/salome" >> ./90${P}
        dodir /etc/env.d
        insinto /etc/env.d
        doins 90${P}
	rm adm_local/Makefile adm_local/unix/make_commence adm_local/unix/make_conclude adm_local/unix/make_omniorb
	insinto "${INSTALL_DIR}"
	doins -r adm_local
	if use doc; then
	   dodoc INSTALL LICENCE
	fi
}