pango-graphite-2.3.ebuild

pango-graphite-2.3.ebuild (text/plain), 1.66 KB, created by Nguyen Thai Ngoc Duy (RETIRED) on 2008-02-16 07:03:44 UTC

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=1

inherit eutils autotools multilib

MP=silgraphite-${PV}
DESCRIPTION="SIL Graphite smart-font engine"
HOMEPAGE="http://scripts.sil.org/RenderingGraphite"
SRC_URI="mirror://sourceforge/${MP}.tar.gz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug"

RDEPEND="dev-libs/glib:2
	>=media-libs/fontconfig-2.2.93
	media-libs/freetype:2
	>=media-libs/silgraphite-2.2.0
	x11-libs/pango"
DEPEND="${RDEPEND}
	>=dev-util/pkgconfig-0.14"

S="${WORKDIR}/${MP}/wrappers/pangographite"

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/${P}-pango-modules.patch
	eautoreconf
}

src_compile() {
	econf \
		$(use_enable debug) \
		|| die "econf failed"
	emake || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	dodoc README || die "dodoc failed"
	rmdir "${D}"/usr/bin
}

# stolen from pango-1.18.4.ebuild

multilib_enabled() {
	has_multilib_profile || ( use x86 && [[ $(get_libdir) == lib32 ]] )
}

pkg_postinst() {
	if [[ "${ROOT}" == / ]] ; then
		einfo "Generating modules listing..."
		local PANGO_CONFDIR=
		if multilib_enabled ; then
			PANGO_CONFDIR=/etc/pango/${CHOST}
		else
			PANGO_CONFDIR=/etc/pango
		fi
		mkdir -p ${PANGO_CONFDIR}

		pango-querymodules >${PANGO_CONFDIR}/pango.modules
	fi
}

pkg_postrm() {
	if [[ "${ROOT}" == / ]] ; then
		einfo "Generating modules listing..."
		local PANGO_CONFDIR=
		if multilib_enabled ; then
			PANGO_CONFDIR=/etc/pango/${CHOST}
		else
			PANGO_CONFDIR=/etc/pango
		fi
		mkdir -p ${PANGO_CONFDIR}

		pango-querymodules >${PANGO_CONFDIR}/pango.modules
	fi
}