improved ebuild

whizzytex-1.3.1.ebuild (text/plain), 1.24 KB, created by Daniel Spoonhower on 2008-01-31 14:44:32 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

inherit elisp eutils

DESCRIPTION="An Emacs minor mode for incremental viewing of LaTeX documents."
SRC_URI="http://cristal.inria.fr/whizzytex/${P}.tgz"

HOMEPAGE="http://cristal.inria.fr/whizzytex/"
LICENSE="LGPL-2.1"

SLOT="0"
KEYWORDS="~x86"

DEPEND="app-text/active-dvi
	app-text/tetex"
RDEPEND="${DEPEND}"

SITEFILE="src/whizzytex-init.el"

src_compile() {
	epatch ${FILESDIR}/gentoo-sitelisp.patch
	./configure -advi 'advi -nogs' -prefix /usr \
	    -emacsdir /usr/share/emacs/site-lisp/${PN} || die "configure failed"
	# Because make will invoke dvi viewers, set the tex fonts output dirs
	export VARTEXFONTS="${T}" TEXMFVAR="${T}" USE_TEXMFVAR=1
	emake all \
	    XEMACSDIR="" \
	    LATEXDIR="/usr/share/texmf/tex/latex/${PN}" \
	    DOCDIR="/usr/share/doc/${P}" \
	    || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" \
	    XEMACSDIR="" \
	    LATEXDIR="/usr/share/texmf/tex/latex/${PN}" \
	    DOCDIR="/usr/share/doc/${P}" \
	    install || die "install failed"

	# Add numeric prefix
	cp "${SITEFILE}" "50${PN}-gentoo.el"
	elisp-site-file-install "50${PN}-gentoo.el"

	dodoc CHANGES COPYING GPL INSTALL
	dohtml doc/whizzytex.html
}