Proposed ebuild

minicom-2.2-r2.ebuild (text/plain), 1.21 KB, created by Andrew Church on 2007-12-24 13:21:57 UTC

# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-dialup/minicom/minicom-2.2-r1.ebuild,v 1.12 2007/06/24 22:05:13 vapier Exp $

inherit eutils

STUPID_NUM="1806"

DESCRIPTION="Serial Communication Program"
HOMEPAGE="http://alioth.debian.org/projects/minicom"
SRC_URI="http://alioth.debian.org/download.php/${STUPID_NUM}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86"
IUSE="nls"

DEPEND_ncurses=">=sys-libs/ncurses-5.2-r3"
DEPEND="${DEPEND_ncurses}
	nls? ( sys-devel/gettext )"
RDEPEND="${DEPEND_ncurses}
	net-dialup/lrzsz"

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/${P}-gentoo-runscript.patch
	epatch "${FILESDIR}"/${P}-one-off.patch
}

src_compile() {
	econf \
		--sysconfdir=/etc/${PN} \
		$(use_enable nls) \
		|| die "econf failed"
	emake || die "emake failed"
}

src_install() {
	emake install DESTDIR="${D}" || die "einstall failed"

	dodoc AUTHORS ChangeLog NEWS README doc/minicom.FAQ
	insinto /etc/minicom
	doins "${FILESDIR}"/minirc.dfl
}

pkg_preinst() {
	[[ -s ${ROOT}/etc/minicom/minirc.dfl ]] \
		&& rm -f "${D}"/etc/minicom/minirc.dfl
}