qt-windows-4.3.3-r1.ebuild

qt-windows-4.3.3-r1.ebuild (text/plain), 6.81 KB, created by Roberto Castagnola on 2007-12-22 09:57:53 UTC

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils flag-o-matic toolchain-funcs

PATCH_VER="0.1"
EPATCH_SOURCE="${WORKDIR}/qt-${PV}-patches"
EPATCH_SUFFIX="patch"

SRCTYPE="opensource-src"
DESCRIPTION="The Qt toolkit is a comprehensive C++ application development framework."
HOMEPAGE="http://www.trolltech.com/"

SRC_URI="ftp://ftp.trolltech.com/pub/qt/source/qt-all-${SRCTYPE}-${PV}.tar.gz
	qt-${PV}-patches-${PATCH_VER}.tar.bz2"
S=${WORKDIR}/qt-all-${SRCTYPE}-${PV}

LICENSE="GPL-2"
SLOT="4"
KEYWORDS="~x86 ~amd64"

IUSE="accessibility debug doc examples gif jpeg mng odbc pch png qt3support sqlite3 tiff zlib"

# cross-compiling need controlled strip
RESTRICT="mirror strip"

pkg_setup() {
	local mingw32_variants="mingw32 i686-mingw32 i586-mingw32 i486-mingw32 i386-mingw32"
	local i
	CTARGET=""
	for i in ${mingw32_variants} ; do
		if type -p ${i}-gcc ; then
			CTARGET=${i}
			break;
		fi
	done

	if [ -z "$CTARGET" ] ; then
		eerror "Before you could emerge qt-windows, you need to install mingw32."
		eerror "Run the following command:"
		eerror "  emerge crossdev"
		eerror "then run _one_ of the following commands:"
		for i in ${mingw32_variants} ; do
			eerror "  crossdev ${i}"
		done
		die "mingw32 is needed"
	fi

	PLATFORM=$(qt_mkspecs_dir)
	XPLATFORM="win32-g++"

	QTPREFIXDIR=/usr/${CTARGET}/usr
	QTBASEDIR=${QTPREFIXDIR}/lib/qt4
	QTBINDIR=${QTPREFIXDIR}/bin
	QTLIBDIR=${QTPREFIXDIR}/lib/qt4
	QTPCDIR=${QTPREFIXDIR}/lib/pkgconfig
	QTDATADIR=${QTPREFIXDIR}/share/qt4
	QTDOCDIR=${QTPREFIXDIR}/share/doc/${PF}
	QTHEADERDIR=${QTPREFIXDIR}/include/qt4
	QTPLUGINDIR=${QTDATADIR}/plugins
	QTSYSCONFDIR=/etc/qt4/${CTARGET}
	QTTRANSDIR=${QTDATADIR}/translations
	QTEXAMPLESDIR=${QTDATADIR}/examples
	QTDEMOSDIR=${QTDATADIR}/demos
}

qt_use() {
	local flag="$1"
	local feature="$1"
	local enableval=

	[[ -n $2 ]] && feature="$2"
	[[ -n $3 ]] && enableval="-$3"

	useq $flag && echo "${enableval}-${feature}" || echo "-no-${feature}"
	return 0
}

qt_mkspecs_dir() {
	 # Allows us to define which mkspecs dir we want to use.
	local spec

	case ${CHOST} in
		*-freebsd*|*-dragonfly*)
			spec="freebsd" ;;
		*-openbsd*)
			spec="openbsd" ;;
		*-netbsd*)
			spec="netbsd" ;;
		*-darwin*)
			spec="darwin" ;;
		*-linux-*|*-linux)
			spec="linux" ;;
		*)
			die "Unknown CHOST, no platform choosed."
	esac

	CXX=$(tc-getCXX)
	if [[ ${CXX/g++/} != ${CXX} ]]; then
		spec="${spec}-g++"
	elif [[ ${CXX/icpc/} != ${CXX} ]]; then
		spec="${spec}-icc"
	else
		die "Unknown compiler ${CXX}."
	fi

	echo "${spec}"
}

src_unpack() {
	unpack ${A}
	cd ${S}

	epatch
	sed -i -e "s:MINGW32:${CTARGET}:" mkspecs/win32-g++/qmake.conf

	# Don't let the user go too overboard with flags.  If you really want to, uncomment
	# out the line below and give 'er a whirl.
	strip-flags
	replace-flags -O3 -O2

	# set c/xxflags and ldflags
	sed -i -e "s:QMAKE_CFLAGS_RELEASE.*=.*:QMAKE_CFLAGS_RELEASE=${CPPFLAGS} ${CFLAGS} ${ASFLAGS}:" \
		-e "s:QMAKE_CXXFLAGS_RELEASE.*=.*:QMAKE_CXXFLAGS_RELEASE=${CPPFLAGS} ${CXXFLAGS} ${ASFLAGS}:" \
		-e "s:QMAKE_LFLAGS_RELEASE.*=.*:QMAKE_LFLAGS_RELEASE=${LDFLAGS}:" \
		-e "/CONFIG/s:$: nostrip:" \
		mkspecs/${PLATFORM}/qmake.conf mkspecs/common/g++.conf

	# Do not link with -rpath. See bug #75181.
	sed -i -e "s:QMAKE_RPATH.*=.*:QMAKE_RPATH=:" \
		mkspecs/${PLATFORM}/qmake.conf mkspecs/common/g++.conf

	# Replace X11R6/ directories, so /usr/X11R6/lib -> /usr/lib
	sed -i -e "s:X11R6/::" mkspecs/${PLATFORM}/qmake.conf mkspecs/common/linux.conf

	sed -i -e "s:CXXFLAGS.*=:CXXFLAGS=${CPPFLAGS} ${CXXFLAGS} ${ASFLAGS} :" \
	    -e "s:LFLAGS.*=:LFLAGS=${LDFLAGS} :" qmake/Makefile.unix
	
	# strip march/mcpu/mtune flags for win32-g++
	filter-flags -march* -mcpu* -mtune*
	append-flags -fno-strict-aliasing
	sed -i -e "s:QMAKE_CFLAGS_RELEASE.*=.*:QMAKE_CFLAGS_RELEASE=${CPPFLAGS} ${CFLAGS} ${ASFLAGS}:" \
		-e "s:QMAKE_CXXFLAGS_RELEASE.*=.*:QMAKE_CXXFLAGS_RELEASE=${CPPFLAGS} ${CXXFLAGS} ${ASFLAGS}:" \
		-e "s:QMAKE_LFLAGS_RELEASE.*=.*:QMAKE_LFLAGS_RELEASE=${LDFLAGS}:" \
		-e "/CONFIG/s:$: nostrip:" \
		mkspecs/${XPLATFORM}/qmake.conf
}

src_compile() {
	export PATH="${S}/bin:${PATH}"
	export LD_LIBRARY_PATH="${S}/lib:${LD_LIBRARY_PATH}"

	myconf="${myconf} -no-mmx -no-3dnow -no-sse -no-sse2"
	myconf="${myconf} -rtti -qt-libpng -qt-libjpeg -qt-libmng -qt-zlib"
	myconf="${myconf} -no-sql-mysql -no-sql-psql -no-sql-ibase -no-sql-sqlite2"
	myconf="${myconf} $(qt_use qt3support) $(qt_use pch)"
	myconf="${myconf} $(qt_use odbc sql-odbc plugin) $(qt_use sqlite3 sql-sqlite plugin)"
	myconf="${myconf} $(qt_use zlib zlib qt) $(qt_use gif gif qt)"
	myconf="${myconf} $(qt_use tiff libtiff qt) $(qt_use png libpng qt)"
	myconf="${myconf} $(qt_use mng libmng qt) $(qt_use jpeg libjpeg qt)"
	
	use debug && myconf="${myconf} -debug -debug-and-release" || myconf="${myconf} -release"
	use examples || myconf="${myconf} -nomake examples -nomake demos"
	
	if use accessibility; then
		if [[ "$(gcc-major-version ${CTARGET})" == "4" ]]; then
			# Disable accessibility support for bug
			# http://gcc.gnu.org/bugzilla/show_bug.cgi?id=27067
			einfo "Accessibility support fails to compile with ${CTARGET}-g++-4: disabled"
			myconf="${myconf} -no-accessibility"
		else
			myconf="${myconf} -accessibility"
		fi
	else
		myconf="${myconf} -no-accessibility"
	fi

	myconf="-stl -verbose -confirm-license -platform ${PLATFORM} -xplatform ${XPLATFORM} \
		-prefix ${QTPREFIXDIR} -bindir ${QTBINDIR} -libdir ${QTLIBDIR} -datadir ${QTDATADIR} \
		-docdir ${QTDOCDIR} -headerdir ${QTHEADERDIR} -plugindir ${QTPLUGINDIR} \
		-sysconfdir ${QTSYSCONFDIR} -translationdir ${QTTRANSDIR} \
		-examplesdir ${QTEXAMPLESDIR} -demosdir ${QTDEMOSDIR} ${myconf}"

	echo ./configure ${myconf}
	./configure ${myconf} || die

	emake || die
}

src_install() {
	export PATH="${S}/bin:${PATH}"
	export LD_LIBRARY_PATH="${S}/lib:${LD_LIBRARY_PATH}"

	make INSTALL_ROOT=${D} install_subtargets || die
	make INSTALL_ROOT=${D} install_mkspecs || die

	# some *.dll are installed twice (in QTBINDIR and in QTLIBDIR)
	# we want them all in QTBINDIR
	mv -f ${D}/${QTLIBDIR}/*.dll ${D}/${QTBINDIR}

	# 'install_qmake' target is missing
	exeinto ${QTBINDIR}
	doexe ${S}/bin/qmake
	# maybe moc, rcc, uic and qmake programs should be installed elsewhere

	if use doc; then
		make INSTALL_ROOT=${D} install_htmldocs || die
	fi

	# Install the translations.  This may get use flagged later somehow
	make INSTALL_ROOT=${D} install_translations || die

	# controlled strip
	env RESTRICT="" CHOST=${CHOST} prepstrip ${D}/${QTBINDIR}
	env RESTRICT="" CHOST=${CTARGET} prepstrip ${D}/${QTLIBDIR}
	# want to strip dlls too
	find ${D} -iname "*.dll" -exec $(tc-getSTRIP ${CTARGET}) --strip-unneeded '{}' \;

	cat > "${T}/44qt4-${CTARGET}" << EOF
XQMAKESPEC=${XPLATFORM}
EOF
	doenvd "${T}/44qt4-${CTARGET}"
	# create symlink to use CTARGET-qmake when cross-compiling
	dosym ${QTBINDIR}/qmake /usr/bin/${CTARGET}-qmake
}