gfs2-2.01.00.ebuild

gfs2-2.01.00.ebuild (text/plain), 1.53 KB, created by r01 on 2007-12-03 18:07:38 UTC

# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit toolchain-funcs linux-info

CLUSTER_RELEASE="${PV}"
MY_P="cluster-${CLUSTER_RELEASE}"

DESCRIPTION="Shared-disk cluster file system"
HOMEPAGE="http://sources.redhat.com/cluster/"
SRC_URI="ftp://sources.redhat.com/pub/cluster/releases/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE=""

DEPEND="=sys-cluster/gfs2-headers-${CLUSTER_RELEASE}*
	=sys-cluster/iddev-${CLUSTER_RELEASE}*
	sys-fs/e2fsprogs
	"

RDEPEND="sys-fs/e2fsprogs
	=sys-cluster/ccs-${CLUSTER_RELEASE}*
	=sys-cluster/cman-${CLUSTER_RELEASE}*
	=sys-cluster/magma-${CLUSTER_RELEASE}*
	=sys-cluster/magma-plugins-${CLUSTER_RELEASE}*
	=sys-cluster/fence-${CLUSTER_RELEASE}*
	"

S="${WORKDIR}/${MY_P}/${PN}"

src_compile() {
	(cd ..; ./configure \
		--sbindir=/usr/sbin \
		--module_dir=/lib/modules/${KV_FULL}/kernel \
		--cc=$(tc-getCC) \
		--kernel_src=${KERNEL_DIR} \
		) || die "configure problem"

	# fix symlinks error
	sed -i \
		-e '\@\tln -sf ${sbindir}/${TARGET1}@s@${sbindir}/@@' \
		mkfs/Makefile fsck/Makefile

	# fix -ggdb CFLAGS
	sed -i \
		-e '/-ggdb/d' \
		edit/Makefile mkfs/Makefile libgfs2/Makefile

	# fix the manual pages have executable bit
	sed -i -e '
		/\tinstall -d/s/install/& -m 0755/; t
		/\tinstall/s/install/& -m 0644/' \
		man/Makefile

	emake || die "compile problem"
}

src_install() {
	emake DESTDIR=${D} install || die "install problem"

	keepdir /etc/cluster || die
	newinitd ${FILESDIR}/${PN}.rc ${PN} || die
}