gxmms2-9999.ebuild

gxmms2-9999.ebuild (text/plain), 1.02 KB, created by Paul Bredbury on 2007-11-05 20:18:44 UTC

# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils git

DESCRIPTION="XMMS2 client using GTK+ 2.6"
HOMEPAGE="http://wejp.k.vu/projects/xmms2/"
SRC_URI=""

EGIT_REPO_URI="git://git.xmms.se/xmms2/gxmms2.git/"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE="gkrellm"

RDEPEND=">=media-sound/xmms2-0.2
	>=x11-libs/gtk+-2.6
	gkrellm? ( >=app-admin/gkrellm-2.2 )"
DEPEND="${RDEPEND}"

src_unpack() {
	git_src_unpack
	cd "${S}"

	# Don't use /usr/local
	sed -i \
		-e 's:\(PREFIX=\).*:\1${D}/usr:' \
		Makefile || die "sed Makefile"
}

src_compile() {
	local target=${PN}
	use gkrellm && target="${PN} gkrellxmms2"

	emake ${target} || die "emake"
}

src_install() {
	emake install_${PN} || die "emake install_${PN}"

	if use gkrellm ; then
		emake install_gkrellxmms2 || die "emake install_gkrellxmms2"
		dodoc README.gkrellxmms2
	fi

	newicon ${PN}src/${PN}_mini.xpm ${PN}.xpm || die "newicon"
	make_desktop_entry ${PN} ${PN} ${PN}.xpm

	dodoc CHANGELOG README
}