etqw-ded-1.2.ebuild

etqw-ded-1.2.ebuild (text/plain), 1.35 KB, created by Paul Bredbury on 2007-11-01 19:03:21 UTC

# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils games

# Handles id's "revisions" in filenames
MY_PV="${PV/_p/-full.r}"
if [[ "${MY_PV}" != *"-full"* ]] ; then
	MY_PV="${PV}-full"
fi

MY_BODY="ETQW-server-${MY_PV}.x86"

DESCRIPTION="Enemy Territory: Quake Wars server"
HOMEPAGE="http://zerowing.idsoftware.com/linux/etqw/"
SRC_URI="mirror://idsoftware/etqw/${MY_BODY}.run"

LICENSE="ETQW"
SLOT="0"
KEYWORDS="~x86"
IUSE=""
RESTRICT="strip"

DEPEND="app-arch/unzip"
RDEPEND=""

S=${WORKDIR}
dir=${GAMES_PREFIX_OPT}/${PN}

QA_TEXTRELS="${dir:1}/pb/pbsv.so
	${dir:1}/pb/pbag.so
	${dir:1}/pb/pbcls.so
	${dir:1}/pb/pbcl.so
	${dir:1}/pb/pbags.so"

QA_EXECSTACK="${dir:1}/libstdc++.so.6
	${dir:1}/etqwded.x86
	${dir:1}/libgcc_s.so.1
	${dir:1}/libmojosetupgui_ncurses.so"

src_unpack() {
	# Cannot use unpack_makeself

	# Determine start of zipfile
	local g=$(grep -uba -m 1 'data/pb' "${DISTDIR}/${MY_BODY}.run" | awk -F ':' '{print $1}')
	g=$((${g} - 60))

	# Extract zipfile
	tail -c +${g} "${DISTDIR}/${MY_BODY}.run" > ${PN}.zip || die
	unpack ./${PN}.zip
	rm -f ${PN}.zip || die
}

src_install() {
	cd data
	insinto "${dir}"
	doins -r * || die "doins"

	exeinto "${dir}"
	doexe etqw-dedicated etqwded.x86 lib* || die "doexe"

	games_make_wrapper ${PN} ./etqwded.x86 "${dir}" "${dir}"

	prepgamesdirs
}