etqw-ded-1.1.ebuild

etqw-ded-1.1.ebuild (text/plain), 1.26 KB, created by Paul Bredbury on 2007-10-07 10:10:59 UTC

# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils games

MY_PV="1.1-full.r3"
MY_BODY="ETQW-server-${MY_PV}.x86"

DESCRIPTION="Enemy Territory: Quake Wars server"
HOMEPAGE="http://zerowing.idsoftware.com/linux/etqw/"
SRC_URI="${MY_BODY}.run"

LICENSE="ETQW"
SLOT="0"
KEYWORDS="~x86"
IUSE=""
RESTRICT="fetch strip"

DEPEND="app-arch/unzip"
RDEPEND=""

S=${WORKDIR}
dir=${GAMES_PREFIX_OPT}/${PN}

QA_TEXTRELS="${dir:1}/data/pb/pbsv.so
	${dir:1}/data/pb/pbag.so
	${dir:1}/data/pb/pbcls.so
	${dir:1}/data/pb/pbcl.so
	${dir:1}/data/pb/pbags.so
	${dir:1}/guis/libmojosetupgui_ncurses.so"

QA_EXECSTACK="${dir:1}/data/libstdc++.so.6
	${dir:1}/data/etqwded.x86
	${dir:1}/data/libgcc_s.so.1
	${dir:1}/guis/libmojosetupgui_ncurses.so"

pkg_nofetch() {
	einfo "Please download ${SRC_URI} from:"
	einfo "  ${HOMEPAGE}"
	einfo "and move it to ${DISTDIR}"
	echo
}

src_unpack() {
	# Cannot use unpack_makeself
	tail -c +677092 "${DISTDIR}/${MY_BODY}.run" > ${PN}.zip
	unpack ./${PN}.zip
	rm ${PN}.zip || die
}

src_install(){
	insinto "${dir}"
	doins -r * || die "doins"

	cd data
	exeinto "${dir}"/data
	doexe et* lib* || die "doexe"

	games_make_wrapper ${PN} ./etqwded.x86 "${dir}"/data "${dir}"/data

	prepgamesdirs
}