x11-libs/qwtplot3d-qt3-0.2.7 ebuild (for Qt3)

qwtplot3d-qt3-0.2.7.ebuild (text/plain), 1.96 KB, created by Federico Cerisola on 2007-09-30 21:01:58 UTC

# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit multilib qt3

MY_P="${P/-qt3/}"
MY_PN="${PN/-qt3/}"
S="${WORKDIR}/${MY_PN}"
MY_PV="${PV/7/6}"

DESCRIPTION="OpenGL and Qt3 based 3D widget library for C++"
HOMEPAGE="http://qwtplot3d.sourceforge.net/"
SRC_URI="mirror://sourceforge/${MY_PN}/${MY_P}.tgz
	doc? ( http://qwtplot3d.sourceforge.net/${MY_PN}-doc.zip )"

LICENSE="ZLIB"
SLOT="0"
IUSE="doc examples"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"

DEPEND="$(qt_min_version 3.3)
	>=sys-apps/sed-4
	doc? ( app-arch/unzip )"
RDEPEND="$(qt_min_version 3.3)"

src_unpack () {
	unpack ${A}
	cd ${S}
	sed -i -e "s:TARGET .* = qwtplot3d:TARGET = qwtplot3d-qt3:" qwtplot3d.pro \
		|| die "sed qwtplot3d.pro failed"
	find . -type f -name "*.pro" | while read file; do
		sed -e 's/.*no-exceptions.*//g' -i ${file}
		echo >> ${file} "QMAKE_CFLAGS_RELEASE += ${CFLAGS}"
		echo >> ${file} "QMAKE_CXXFLAGS_RELEASE += ${CXXFLAGS}"
	done
	find examples -type f -name "*.pro" | while read file; do
		echo >> ${file} "INCLUDEPATH += /usr/include/qwtplot3d-qt3"
		sed -e "s:-lqwtplot3d:-lqwtplot3d-qt3:" -i ${file}
	done
}

src_compile () {
	addwrite ${QTDIR}/etc/settings
	eqmake3 qwtplot3d.pro || die "qmake failed."
	emake || die "emake failed."
}

src_install () {
	dolib lib/libqwtplot3d-qt3.so.${MY_PV} || die "dolib failed."
	# do NOT remove these symlinks, other packages depend on it
	dosym libqwtplot3d-qt3.so.${MY_PV} /usr/$(get_libdir)/libqwtplot3d-qt3.so
	dosym libqwtplot3d-qt3.so.${MY_PV} /usr/$(get_libdir)/libqwtplot3d-qt3.so.${MY_PV/.*/}
	chmod -R 644 examples
	chmod 755 examples examples/simpleplot/ examples/mesh2/ \
		examples/enrichments/ examples/axes/ examples/autoswitch/ \
		examples/axes/src/
	mkdir -p ${D}/usr/include/qwtplot3d-qt3/
	install include/* ${D}/usr/include/qwtplot3d-qt3/
	if use examples; then
		dodir /usr/share/doc/${PF}
		cp -pPR examples ${D}/usr/share/doc/${PF}/
	fi
	use doc && dohtml -r doc/web/doxygen/*
}