My ebuild proposal

arptables-0.0.3.3.ebuild (text/plain), 1.20 KB, created by Olivier Huber on 2007-08-23 13:47:53 UTC

# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-firewall/arptables/arptables-0.0.3.ebuild,v 1.8 2005/09/22 03:03:35 vapier Exp $

inherit versionator eutils toolchain-funcs multilib

MY_PV=$(replace_version_separator 3 '-' )
MY_P="${PN}-v${MY_PV}"

DESCRIPTION="set up, maintain, and inspect the tables of ARP rules in the Linux kernel"
HOMEPAGE="http://ebtables.sourceforge.net/"
SRC_URI="mirror://sourceforge/ebtables/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE=""

S=${WORKDIR}/${MY_P}

DEPEND="virtual/libc"

src_unpack() {
	unpack ${A}
	cd "${S}"

#Fix scripts to be built during make
	epatch "${FILESDIR}"/${P}-scripts-build.patch

	sed -i -e "s,MANDIR:=\$(PREFIX)/man,MANDIR:=/usr/share/man," \
		-e "s,BINDIR:=\$(PREFIX)/sbin,BINDIR:=/sbin," \
		-e "s,INITDIR:=/etc/rc.d/init.d,INITDIR:=/usr/share/doc/${PF}," \
		-e "s,SYSCONFIGDIR:=/etc/sysconfig,SYSCONFIGDIR:=/usr/share/doc/${PF}," \
		-e "s,LIBDIR:=\$(PREFIX)/lib,LIBDIR:=/$(get_libdir)/arptables," Makefile

}

src_compile() {
	emake CC="$(tc-getCC)" || die "emake failed"
}

src_install() {

	make DESTDIR="${D}" install || die
}