fms-1.3.0_rc1.ebuild

fms-1.3.0_rc1.ebuild (text/plain), 1.86 KB, created by Justin Bronder (RETIRED) on 2007-07-06 14:49:30 UTC

# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header:$

inherit autotools

MY_P=${P/_/}
DESCRIPTION="Replacement for mx/gm_mapper on Myrinet networks"
HOMEPAGE="http://www.myri.com/scs/fms/"
SRC_URI="http://www.myri.com/ftp/pub/FMS/${MY_P}.tar.gz"

LICENSE="MYRICOM"

SLOT="0"
KEYWORDS="~amd64 ~ppc64 ~x86"
IUSE="gm mx"

DEPEND="gm? (sys-cluster/gm)
		mx? (sys-cluster/mx)"

RESTRICT="fetch nomirror"

# fms-1.2.5.tar.gz unpacks to fma
S="${WORKDIR}/fma"

pkg_setup() {
	if [ -z "${EXTRA_ECONF}" ] || \
		[ -z "$(echo ${EXTRA_ECONF} | egrep '.*--with-fms-server')" ]; then
		einfo 
		einfo "You may want to modify EXTRA_ECONF to include --with-fms-server=<server_name>.  This will allow"
		einfo "the use of most fm_* commands without specifiying the einfo server using -s."
		einfo
		epause 5
	fi

	if use gm && use mx ; then
		eerror "fms cannot handle gm and mx"
		die
	elif ! use gm && ! use mx ; then
		eerror "fms needs to know which fabric to use"
		die
	fi
}

src_unpack() {
	unpack "${A}"
	cd "${S}"

	# Allow productinfo to be outside of $(prefix)/productinfo
	epatch ${FILESDIR}/fms-seperate-productinfo_dir.patch

	# Allow users to set their CFLAGS
	sed -i 's/@CF@/@CFLAGS@/' Makefile.in
	eautoreconf
}
	
src_compile() {
	local confstr

	if use gm ; then
		confstr="--with-myri-api=gm --with-myri-install-dir=/usr"
	fi

	if use mx ; then
		confstr="--with-myri-api=mx --with-myri-install-dir=/usr"
	fi


	econf \
		${confstr} \
		--datarootdir=/usr/share/fms \
		--with-fms-run=/var/run/fms \
		|| die "econf failed"

	emake || die "emake failed"
}

src_install() {
	dodir /usr/share/fms
	make DESTDIR="${D}" install || die "make install failed"
	dodoc CHANGES README 
	dodir /var/run/fms
	keepdir /var/run/fms
	newinitd ${FILESDIR}/fms-init.d fms
	newinitd ${FILESDIR}/fma-init.d fma
	newconfd ${FILESDIR}/fms-conf.d fms
}