kingpin-1.20.ebuild

kingpin-1.20.ebuild (text/plain), 2.19 KB, created by Paul Bredbury on 2007-07-06 13:03:41 UTC

# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils multilib games

DESCRIPTION="Violent gang warfare"
HOMEPAGE="http://www.liflg.org/?catid=6&gameid=2"
SRC_URI="http://ftp.linuxcenter.ru/projects/games/Installers/Kingpin/${PN}_${PV}-english.run"

LICENSE="as-is"
SLOT="0"
# Untested on amd64
KEYWORDS="~x86"
IUSE=""
RESTRICT="strip"

RDEPEND="
	x86? (
		virtual/opengl
		x11-libs/libX11
		x11-libs/libXau
		x11-libs/libXdmcp
		x11-libs/libXext )
	amd64? (
		app-emulation/emul-linux-x86-sdl
		app-emulation/emul-linux-x86-xlibs )"
# unshield-0.2 creates some empty files, so need recent version
DEPEND=">=app-arch/unshield-0.5-r1"

S=${WORKDIR}
dir=${GAMES_PREFIX_OPT}/${PN}

QA_TEXTRELS="${dir:1}/kphack.so
	${dir:1}/ref_gl.so
	${dir:1}/ref_glx.so"

pkg_setup() {
	games_pkg_setup

	cdrom_get_cds kingpin/data1.cab
}

src_unpack() {
	unpack_makeself kingpin_${PV}-english.run
	unpack ../work/{kingpin_${PV},kphack}.tar.gz

	# Use native unshield, to prevent error during extraction
	sed -i \
		-e "s:\$GAME_SETUP/setup.data/unshield:unshield:" \
		setup.data/install-disc1.sh || die "sed install-disc1.sh"

	chmod og+x setup.data/install-disc1.sh
	SETUP_CDROMPATH="${CDROM_ROOT}" ./setup.data/install-disc1.sh \
		|| die "install-disc1.sh"

	# Renaming required for the files to be found
	local d
	for d in thug{,_sit} ; do
		mv common_files/main/models/actors/${d}/{l,L}_pstl.mdx || die
		mv common_files/main/models/actors/${d}/{r,R}_pstl.mdx || die
	done

	echo "${dir}" > kingpin.conf || die "echo"

	if use amd64 ; then
		# Untested on amd64
		sed -i \
			-e "s:/usr/lib:/usr/$(get_libdir):" \
			${PN} || die "sed ${PN} amd64"
	fi
}

src_install() {
	insinto "${dir}"
	doins -r {common_files,mature_files,program_executable_files,.}/main \
		kingpin.conf README* || die "doins main"

	exeinto "${dir}"
	doexe ${PN}.x86 bin/${PN} *.so || die "doexe"

	exeinto "${dir}"/main
	doexe main/*.so || die "doexe main"

	doicon ${PN}.xpm || die "doicon"
	games_make_wrapper ${PN} ./${PN} "${dir}" "${dir}"
	make_desktop_entry ${PN} "Kingpin" ${PN}.xpm

	prepgamesdirs
}

pkg_postinst() {
	games_pkg_postinst

	elog "Mount the Kingpin CD before playing."
	echo
}