wengophone-2.1.1.ebuild

wengophone-2.1.1.ebuild (text/plain), 2.89 KB, created by Chí-Thanh Christopher Nguyễn on 2007-07-04 04:30:46 UTC

# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/www/viewcvs.gentoo.org/raw_cvs/gentoo-x86/net-im/wengophone/Attic/wengophone-2.0_rc2.ebuild,v 1.7 2007/04/14 12:51:57 genstef dead $

inherit eutils toolchain-funcs

DESCRIPTION="Wengophone NG is a VoIP client featuring the SIP protcol"
HOMEPAGE="http://dev.openwengo.com"
SRC_URI="http://download.wengo.com/nightlybuilds/universal/sources/openwengo/${PV}/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="alsa oss portaudio xv"

RDEPEND="dev-libs/boost
	|| ( >=dev-libs/boost-1.34 >=sys-devel/gcc-4.2 <sys-devel/gcc-4.1 )
	dev-libs/glib
	dev-libs/openssl
	alsa? ( media-libs/alsa-lib )
	net-libs/gnutls
	media-video/ffmpeg
	|| ( x11-libs/libX11 virtual/x11 )
	>=x11-libs/qt-4.1
	xv? ( x11-libs/libXv )"

DEPEND="${RDEPEND}
	media-libs/speex
	>=dev-util/cmake-2.4.4"
S=${WORKDIR}/${P/_/-}

pkg_setup() {
	if has_version '=dev-libs/boost-1.33*' && ! built_with_use dev-libs/boost threads; then
		eerror "This package requires dev-libs/boost compiled with threads support."
		eerror "Please reemerge dev-libs/boost with USE=\"threads\"."
		die "Please reemerge dev-libs/boost with USE=\"threads\"."
	fi

	if has_version '=dev-libs/boost-1.33*' && egrep -s "GCC: \(GNU\) 4\.1" /usr/lib/libboost_thread.so; then
		eerror "The combination of boost-1.33 and gcc-4.1 causes wengophone"
		eerror "to run unstable or not at all. Use a different version of boost"
		eerror "or compile it with a different version of gcc."
		die "dev-libs/boost-1.33 was compiled with gcc-4.1"
	fi

}

src_compile() {

	local mycmakeflags

	if ! has_version '>=net-misc/curl-7.16.1'; then
		elog "curl 7.16.1 or later not installed, using internal curl"
		mycmakeflags="${mycmakeflags} -DCURL_INTERNAL=ON"		
	fi

	if use portaudio; then
		mycmakeflags="${mycmakeflags} -DOWSOUND_PORTAUDIO_SUPPORT=ON"
	else
		mycmakeflags="${mycmakeflags} -DOWSOUND_PORTAUDIO_SUPPORT=OFF"
	fi

	if use alsa; then
		mycmakeflags="${mycmakeflags} -DPHAPI_AUDIO_ALSA_SUPPORT=ON \
			-DPORTAUDIO_ALSA_SUPPORT=ON"
	else
		mycmakeflags="${mycmakeflags} -DPHAPI_AUDIO_ALSA_SUPPORT=OFF \
			-DPORTAUDIO_ALSA_SUPPORT=OFF"		
	fi

	if use oss; then
		mycmakeflags="${mycmakeflags} -DPHAPI_AUDIO_OSS_SUPPORT=ON \
			-DPORTAUDIO_OSS_SUPPORT=ON"
	else
		mycmakeflags="${mycmakeflags} -DPHAPI_AUDIO_OSS_SUPPORT=OFF \
			-DPORTAUDIO_OSS_SUPPORT=OFF"		
	fi

	if use xv; then
		mycmakeflags="${mycmakeflags} -DWENGOPHONE_XV_SUPPORT=ON"
	else
		mycmakeflags="${mycmakeflags} -DWENGOPHONE_XV_SUPPORT=OFF"
	fi

	cd ${S}/build
	cmake -DCMAKE_INSTALL_PREFIX="/usr" ${mycmakeflags} \
		.. || die "cmake failed"
	emake || die "make failed"
}

src_install() {
	cd ${S}/build
	emake DESTDIR=${D} install || die "install failed"
	domenu ../wengophone/res/wengophone.desktop
	doicon ../wengophone/res/wengophone_64x64.png
}

pkg_postinst() {
	elog 'execute "qtwengophone" to start wengophone'
}