conntrack-tools-0.9.3.ebuild

conntrack-tools-0.9.3.ebuild (text/plain), 1.26 KB, created by Natanael Copa on 2007-06-21 11:06:16 UTC

# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit linux-info

DESCRIPTION="Netfilter's connection tracking tools"
HOMEPAGE="http://people.netfilter.org/pablo/conntrack-tools/"
SRC_URI="http://www.netfilter.org/projects/conntrack-tools/files/${P}.tar.bz2"

LICENSE="GPL"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

RDEPEND=">=net-libs/libnfnetlink-0.0.25
	>=net-libs/libnetfilter_conntrack-0.0.75
	!net-firewall/conntrack"

DEPEND="${RDEPEND}
	>=sys-kernel/linux-headers-2.6.18"

pkg_setup() {
	linux-info_pkg_setup
	kernel_is lt 2 6 14 && die "${PN} requires at least 2.6.14	kernel version"

	# netfilter core team has changed some option names in .config with 
	# kernel 2.6.20
	if kernel_is lt 2 6 20
		then
			CONFIG_CHECK="IP_NF_CONNTRACK_NETLINK"
		else
			CONFIG_CHECK="NF_CT_NETLINK"
	fi
	check_extra_config
}

src_compile() {
	econf || die "econf failed"
	emake || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	dodoc AUTHORS ChangeLog

	newinitd "${FILESDIR}/conntrackd.initd" conntrackd
	newconfd "${FILESDIR}/conntrackd.confd" conntrackd

	# copy example config from examples/stats
	insinto /etc/conntrackd
	doins "${S}/examples/stats/conntrackd.conf"
}