Sunflow ebuild for svn version

sunflow-9999.ebuild (text/plain), 2.05 KB, created by Philipp Hagemeister on 2007-06-03 23:15:42 UTC

# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils subversion java-pkg-2 java-ant-2

# This is the svn version of the Sunflow ebuild.

IUSE="blender doc examples gnome source"
# blender: Install blender exporter.
# doc: Install javadoc (plus README and LICENSE to the doc directory)
# examples: Install examples. Because they aren't always released with a sunflow version, they can be found at media-gfx/sunflow-examples.
#	Not setting this flag means we need to patch the ant buildfile.
# gnome: calls GNOME reinitialization after installation/uninstallation
# source: Install a zip file of the source. This can be used for linking to code in an IDE.

ESVN_REPO_URI="http://sunflow.svn.sourceforge.net/svnroot/sunflow/trunk"

DESCRIPTION="a rendering system written in Java"
HOMEPAGE="http://sunflow.sf.net/"
SRC_URI=""

SLOT="0"
LICENSE="MIT"
KEYWORDS="~amd64 ~ppc ~x86"

RDEPEND=">=virtual/jre-1.6"

DEPEND="${RDEPEND}
	>=virtual/jdk-1.6
	dev-java/ant-core
	dev-java/janino
	source? ( app-arch/zip )
	blender? ( media-gfx/blender )
	examples? ( media-gfx/sunflow-examples )"

S=${WORKDIR}/${PN}

src_unpack() {
	subversion_src_unpack
}

src_compile() {
	eant
}

src_install() {
	dodir "/usr/share/${PN}"
	
	java-pkg_jarinto "/usr/share/${PN}"
	java-pkg_newjar "${S}/release/${PN}.jar"
	
	java-pkg_jarfrom --into "${D}/usr/share/sunflow" janino || die
	java-pkg_dolauncher "${PN}" --java_args "-Xmx2G -server" || die
	
	if use blender; then
		insinto "/usr/share/blender/scripts"
		doins "${S}/exporters/blender/sunflow_export.py" || die
	fi
	
	insinto "/usr/share/pixmaps"
	doins "${FILESDIR}/${PN}.svg"
	doins "${FILESDIR}/${PN}.png"
	insinto "/usr/share/applications"
	doins "${FILESDIR}/${PN}.desktop"
	
	doman "${FILESDIR}/sunflow.1"
	
	if use doc; then
		dodoc "${S}/LICENSE" "${S}/README"
		
		java-pkg_dojavadoc "${S}/release/javadoc"
	fi
	
	if use source; then
		java-pkg_dosrc "${S}/src"
	fi
}


pkg_postinst() {
	use gnome && gnome2_pkg_postinst
}

pkg_postrm() {
	use gnome && gnome2_pkg_postrm
}